Set Registry Value for All Users

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Set Registry Value for All Users

Logged in as: Guest

arrSession:exec spGetSession 2,16,51805

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Set Registry Value for All Users
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Set Registry Value for All Users - 9/13/2007 5:08:02 AM

DiGiTAL.SkReAM

Posts: 1095
Score: 6
Joined: 9/6/2005
From: Florida, USA
Status: offline

This subroutine allows you to set a particular registry key to a particular value for all the users on that computer, and any future users as well.

This sub is a derivative of Ginolard's Excellent UserHives sub at http://www.visualbasicscript.com/fb.aspx?m=47074

usage:

SetAllUsersRegKey "Software\Microsoft\Command Processor\CompletionChar",00000009,"REG_DWORD"

Sub SetAllUsersRegKey(sKeyName,sData,sType)
Dim oShell, sCommand, oUserRegDic, oSubFolder, sKey, oReg, sSubKey, aRegKeys, aDesktopKeys
Set oShell = CreateObject("Wscript.Shell")
sCommand = "%comspec% /c " & oShell.ExpandEnvironmentStrings("%WINDIR%") & "\System32\Reg.exe "
oShell.RegWrite "HKCU\" & sKeyName,sData,sType
Set oUserRegDic = CreateObject("Scripting.Dictionary")
 For Each oSubFolder In oFSO.GetFolder(Left(oShell.SpecialFolders(0),InStr(oShell.SpecialFolders(0),"\All ")-1)).Subfolders
  On Error Resume Next 
   oUserRegDic.Add oSubFolder,oSubFolder.Name
  On Error GoTo 0 
 Next
 For Each sKey In oUserRegDic.Keys 
  oShell.Run sCommand & "LOAD " & Chr(34) & "HKU\" & oUserRegDic.Item(sKey) & Chr(34) & " " & chr(34) & sKey & "\NTUser.dat" & Chr(34),0,True 
 Next
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
oReg.EnumKey HKEY_USERS, "", aRegKeys
 For Each sSubkey In aRegKeys
  oReg.EnumKey HKEY_USERS, sSubkey & "\Control Panel\Desktop", aDesktopKeys
   If Not IsNull(aDesktopKeys) Then 
    oShell.RegWrite "HKEY_USERS\" & sSubkey & "\" & sKeyName,sData,sType
   End If
 Next
 For Each sKey In oUserRegDic.Keys 
  oShell.Run sCommand & "UNLOAD " & Chr(34) & "HKU\" & oUserRegDic.Item(sKey) & Chr(34),0,True 
 Next
End Sub

_____________________________

"There's the one man who learns by reading, the two men that learn by watching, and the rest of us have to pee on the electric fence for ourselves." - Roy Rogers

"Would you like to touch my monkey?" - Dieter (Mike Meyers)