Task Explorer

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Task Explorer

Logged in as: Guest

arrSession:exec spGetSession 2,16,51868

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Task Explorer
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Task Explorer - 9/16/2007 1:06:21 PM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

This is just a fun script I wrote.

The goal was to create a cool HTA application with lots of features. It's designed for and tested only on XP Pro, but I have made it as bullet proof as I can so I would appreciate any feedback regarding structure or bugs. Adding another button that sets the displayed task onto a different computer would be relatively easy and would make the script really useful. In fact feel free to take it and add/change any features you like.

Save and run the code with the following filename " TaskExplorer.HTA "

<html>
<head>
<title>MJP's Task Explorer</title>
<HTA:APPLICATION 
    ID="MJP"
    APPLICATIONNAME="MJP's Task Explorer"
    SCROLL="yes"
    SINGLEINSTANCE="yes"
    WINDOWSTATE="maximize"
> 
</head>

<SCRIPT Language="VBScript">
dim playfilename
dim strComputer, strThisComputer
Dim objShell
Dim objFSO,objFile
Dim objNetwork
dim selecttask
Const ForReading = 1
Const ForWriting = 2
Set objShell = CreateObject("WScript.Shell")
Set objFSO=CreateObject("Scripting.FileSystemObject")
strTempDir=objShell.ExpandEnvironmentStrings("%temp%")
strTempFile="MJP-Tasks.csv"
strCSV=strTempDir & "\" & strTempFile
strINI= strTempDir & "\MJP-Tasks.ini"
SelectTask=0

Sub Window_Onload
'Find this machine's name to use as an initial value. 
  Set objNetwork=CreateObject("WScript.Network")
  strComputer=objNetwork.ComputerName
  machinename.innerhtml=strComputer
  strThisComputer = strComputer
'Check the operating system version before executing the script. 
OSVersion strThisComputer
'Check if INI file exists and use computer name from that instead
if objFSO.FileExists(strINI) then
  Set objFile = objFSO.OpenTextFile(strINI, ForReading)
  strLineINI = objFile.ReadLine
If Not Reachable(strLineINI) Then 
   'unreachable computer name in INI file.
else
      machinename.innerhtml=strLineINI
End If
end if
'Check if Script is running for the first time
if objFSO.FileExists(strCSV) then
'
else
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Logon Sound.wav"
  playfile playfilename
end if
runscript
End Sub

Function Reachable(strComputer)
 Dim wmiQuery : wmiQuery = "Select * From Win32_PingStatus Where Address = '" & _
                           strComputer & "'"
 Dim objWMIService : Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
 Dim objPing : Set objPing = objWMIService.ExecQuery(wmiQuery)
 Dim objStatus
 For Each objStatus in objPing
     If IsNull(objStatus.StatusCode) Or objStatus.Statuscode<>0 Then
         Reachable = False
     Else
         Reachable = True
     End If
 Next
End Function

sub RestartScript
  Location.Reload(True)
end sub

sub SelectedTaskNo
selecttask=thetasknames.value
runscript
end sub

Sub RunScript
  strComputer=machinename.innerhtml
  if Taskcount.InnerHTML = "x" then
selecttask=1
  end if   
' ping remote computer and quit if it is not available
If Not Reachable(strComputer) Then 
  ScriptInfo.innerhtml = UCASE(NewMachineName.Value) & " is unreachable or offline. "
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Hardware Fail.wav"
  playfile playfilename
  exit sub
End If
' Excecute command - Query computer for scheduled task information
  strCMD="cmd /c c:\windows\system32\Schtasks.exe /S " & strComputer & " /query /fo csv /NH /v > " & strCSV
  objShell.Run strCmd,0,True
'only run if file exists size is greater than 0
if objFSO.FileExists(strCSV) then
  Const ForReading = 1
  Const ForWriting = 2
  Set objFile = objFSO.OpenTextFile(strCSV, ForReading)
'Clean up file - remove blank line at top
Do Until objFile.AtEndOfStream
   strLine = objFile.Readline
   strLine = Trim(strLine)
   If Len(strLine) > 0 Then
       strNewContents = strNewContents & strLine & vbCrLf
   End If
Loop
  objFile.Close
  Set objFile = objFSO.OpenTextFile(strCSV, ForWriting)
  objFile.Write strNewContents
  objFile.Close

' Count the number of lines in file - The number of tasks and populate dropdown box
if Taskcount.InnerHTML = "x" then 
  Taskcountx=1
  Set objFile = objFSO.OpenTextFile(strCSV, ForReading)
  Do While Not objFile.AtEndOfStream
  strLine = objFile.ReadLine
If strLine = "INFO: There are no scheduled tasks present in the system." then
   exit do
end if
  readCSVfile = Split(strLine , chr(34)&","&chr(34))
       dim objOption
Set objOption = Document.createElement("OPTION")
       objOption.Text = readCSVfile(1)
       objOption.Value = TaskCountx
       TheTaskNames.Add(objOption)
       TaskCountx=Taskcountx + 1                       
  Loop
  objFile.Close
Taskcount.InnerHTML = TaskCountx -1
end if
'Disable the delete task button if there are no tasks to delete
if Taskcount.InnerHTML=0 then
  run_button4.disabled =true
end if
'Read a specific line of the csv file and populate values for table - note there is one task on each line of the file.
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(strCSV, ForReading)
For i = 1 to SelectTask
  strNextLine = objTextFile.ReadLine
Next
objTextFile.Close
If strNextLine = "INFO: There are no scheduled tasks present in the system." then
  ScriptInfo.innerhtml = "There are no scheduled tasks present on the computer " & UCASE(strComputer)
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Hardware Fail.wav"
  playfile playfilename
  exit sub
end if
  readCSVfile = Split(strNextLine , chr(34)&","&chr(34))
HostName.value = Replace(readCSVfile(0), chr(34), "")
TaskNamex.value = Replace(readCSVfile(1), chr(34), "")
NextRunTime.value = Replace(readCSVfile(2), chr(34), "")
on error resume next
Status.value = Replace(readCSVfile(3), chr(34), "")
on error goto 0
LastRunTime.value = Replace(readCSVfile(4), chr(34), "")
LastResult.value = Replace(readCSVfile(5), chr(34), "")
Creator.value = Replace(readCSVfile(6), chr(34), "")
Schedule.value = Replace(readCSVfile(7), chr(34), "")
TaskToRun.value = Replace(readCSVfile(8), chr(34), "")
StartIn.value = Replace(readCSVfile(9), chr(34), "")
Comment.value = Replace(readCSVfile(10), chr(34), "")
ScheduledTaskState.value = Replace(readCSVfile(11), chr(34), "")
ScheduledType.value = Replace(readCSVfile(12), chr(34), "")
StartTime.value = Replace(readCSVfile(13), chr(34), "")
StartDate.value = Replace(readCSVfile(14), chr(34), "")
EndDate.value = Replace(readCSVfile(15), chr(34), "")
Days.value = Replace(readCSVfile(16), chr(34), "")
Months.value = Replace(readCSVfile(17), chr(34), "")
RunAsUser.value = Replace(readCSVfile(18), chr(34), "")
DeleteTaskIfNotRescheduled.value = Replace(readCSVfile(19), chr(34), "")
StopTaskIfRunsXHoursandXMins.value = Replace(readCSVfile(20), chr(34), "")
RepeatEvery.value = Replace(readCSVfile(21), chr(34), "")
RepeatUntilTime.value = Replace(readCSVfile(22), chr(34), "")
RepeatUntilDuration.value = Replace(readCSVfile(23), chr(34), "")
RepeatStopIfStillRunning.value = Replace(readCSVfile(24), chr(34), "")
IdleTime.value = Replace(readCSVfile(25), chr(34), "")
PowerManagement.value = Replace(readCSVfile(26), chr(34), "")
End If 
End Sub

' Query a different machine
Sub change
if NewMachineName.Value = "" or NewMachineName.Value = "Remote Host" then
' bad entry - ignore
else
' before trying ping it
If Not Reachable(NewMachineName.Value) Then 
  ScriptInfo.innerhtml = UCASE(NewMachineName.Value) & " is unreachable or offline. "
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Hardware Fail.wav"
  playfile playfilename
  exit sub
End If
' create ini file in temp directory with new machine's name
   machinename.innerhtml=UCASE(NewMachineName.Value)
   MachineINI=machinename.innerhtml
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile(strINI)
objFile.WriteLine(MachineINI) 
objFile.Close
RestartScript
end if
End Sub

' print the current page
sub printme
  catwoman.innerhtml="<img src=http://www.visualbasicscript.com/avatars/Catwoman2.gif>"
  Window.Print()
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Print complete.wav"
  playfile playfilename
  catwoman.innerhtml=""
end sub

' Delete the currently displayed task
sub delTask
delTaskWarning = MsgBox ("Are you sure you want to delete sheduled task "&chr(34)&TaskNamex.value&chr(34)&" From machine "&HostName.value, 276, "Warning")
if delTaskWarning = 6 then
  strDelCMD="cmd /c c:\windows\system32\Schtasks.exe /S " & HostName.value & " /Delete /TN "&chr(34)& TaskNamex.value &chr(34)&" /F"
  objShell.Run strDelCMD,0,True
  RestartScript
end if
end sub

' play a wav file passed to this function
Function Playfile(filenamex)
on error resume next
Set objPlayer = CreateObject("WMPlayer.OCX.7" )
objPlayer.URL = filenamex
while objPlayer.playstate = 9 OR objPlayer.playstate = 3
sleep 2
wend
on error goto 0
End Function

' HTA sleep work around
Sub Sleep(strSeconds)
  strCmd = "%COMSPEC% /c ping -n " & strSeconds & " 127.0.0.1>nul"
  objShell.Run strCmd,0,1
End Sub

' Determine the operatin system version of the machine you are running script from
Sub OSVersion(strThisComputer)
On Error Resume Next
  Set objWMI = GetObject("winmgmts:\\" & strThisComputer & "\root\cimv2")
  Set colItems = objWMI.ExecQuery("Select * from Win32_OperatingSystem",,48)
For Each objItem in colItems
  VerBigX = objItem.Version
  VerBig = Left(VerBigX,3)
Next
Select Case VerBig
  Case "6.0" OSystem = "Vista"
  Case "5.2" OSystem = "WindowsServer2003"
  Case "5.1" OSystem = "XP"
  Case "5.0" OSystem = "W2K"
  Case "4.0" OSystem = "NT4"
  Case Else OSystem = "Unknown"
End Select
on error goto 0
if OSystem = "XP" then
  ScriptInfo.innerhtml="Working - "&OSystem&" Version "&VerBigX
else
  ScriptInfo.innerhtml="Warning this script was designed for XP. Not "& Osystem &" Version "&VerBigX
  playfilename="\\"&strThisComputer&"\c$\WINDOWS\Media\Windows XP Hardware Fail.wav"
  playfile playfilename
end if
end sub
</SCRIPT>

<body bgcolor="#000080" text="FFFFFF">
<table width="100%" border=0>
 <tr>
   <td width="30%" valign="center"><font face="tahoma" color="#FFFF00" size=+2><b><span id=MachineName>x</span></b></font></td>
   <td width="70%" align="right" valign="center"><font face="tahoma" color="#FFFF00" ><b><span id=ScriptInfo>Working</span></b></font></td>
 </tr>
</table>

<br><b>
<font face="tahoma">
Enter Computer Name <input type="text" name="NewMachineName" value="Remote Host" size="15">
<input id=runbutton5  class="button" type="button" value="Query" name="run_button5"  onClick="Change">
<input id=runbutton3  class="button" type="button" value="Print" name="run_button3"  onClick="PrintMe">
<span id=Taskcount>x</span> Tasks <select size="1" name="TheTaskNames" onChange="SelectedTaskNo"></select>
<input id=runbutton4  class="button" type="button" value="Delete Task" name="run_button4"  onClick="DelTask">
<input id=runbutton2  class="button" type="button" value="Refresh" name="run_button2"  onClick="RestartScript">
<br><br></b>

<table bgcolor="#000080" border=0 cellspacing="0">
 <tr>
   <td width="280" valign="top" align="right">Host Name: </td>
   <td valign="top"><textarea name="HostName" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Task Name: </td>
   <td valign="top"><textarea name="TaskNamex" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Next Run Time: </td>
   <td valign="top"><textarea name="NextRunTime" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Status: </td>
   <td valign="top"><textarea name="Status" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Last Run Time: </td>
   <td valign="top"><textarea name="LastRunTime" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Last Result: </td>
   <td valign="top"><textarea name="LastResult" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Creator: </td>
   <td valign="top"><textarea name="Creator" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Schedule: </td>
   <td valign="top"><textarea name="Schedule" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Task To Run: </td>
   <td valign="top"><textarea name="TaskToRun" rows="2" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Start In: </td>
   <td valign="top"><textarea name="StartIn" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Comment: </td>
   <td valign="top"><textarea name="Comment" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Scheduled TaskState: </td>
   <td valign="top"><textarea name="ScheduledTaskState" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Scheduled Type: </td>
   <td valign="top"><textarea name="ScheduledType" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Start Time: </td>
   <td valign="top"><textarea name="StartTime" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Start Date: </td>
   <td valign="top"><textarea name="StartDate" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">End Date: </td>
   <td valign="top"><textarea name="EndDate" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Days: </td>
   <td valign="top"><textarea name="Days" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Months: </td>
   <td valign="top"><textarea name="Months" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Run As User: </td>
   <td valign="top"><textarea name="RunAsUser" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Delete Task If Not Rescheduled: </td>
   <td valign="top"><textarea name="DeleteTaskIfNotRescheduled" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Stop Task If Runs X Hours and X Mins: </td>
   <td valign="top"><textarea name="StopTaskIfRunsXHoursandXMins" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Repeat Every: </td>
   <td valign="top"><textarea name="RepeatEvery" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Repeat Until Time: </td>
   <td valign="top"><textarea name="RepeatUntilTime" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Repeat Until Duration: </td>
   <td valign="top"><textarea name="RepeatUntilDuration" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Repeat Stop If Still Running: </td>
   <td valign="top"><textarea name="RepeatStopIfStillRunning" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">IdleTime: </td>
   <td valign="top"><textarea name="IdleTime" rows="1" cols="80"></textarea></td>
 </tr>
 <tr>
   <td width="280" valign="top" align="right">Power Management: </td>
   <td valign="top"><textarea name="PowerManagement" rows="1" cols="80"></textarea></td>
 </tr>
</table>
<br>
</font>
<p align=right>  <span id=Catwoman></span>  <i><font size=-1> Task Explorer Version1 for XP by MJP 2007</font></i></p>

</body>
</html>

Post #: 1

RE: Task Explorer - 9/17/2007 2:36:39 AM

dm_4ever

Posts: 2220
Score: 32
Joined: 6/29/2006
From: Orange County, California
Status: offline

This is a neat HTA. Thanks for sharing.

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Meg)

Post #: 2

RE: Task Explorer - 9/17/2007 9:46:02 AM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Thanks for the compliment dm_4ever it probably has snippets from your scripts in it.
It uses the schtasks.exe to get the tasks and I just tested it and it retrieves tasks from 2003 servers beautifully, it also runs from a 2003 server too but you don�t hear the sound effects and you get a warning message about the operating system version which you could easily remove if you wanted.

(in reply to dm_4ever)

Post #: 3

RE: Task Explorer - 12/12/2007 3:45:08 PM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Here is a vbs version the monitors for changes to sheduled tasks.

' Script by MJP 2007
' Monitor computer for changes to sheduled tasks
' Requires Schtasks.exe which ships with XP Pro - if you have XP Home and can find a copy of Schtasks.exe, it works if you copy it to c:\windows\system32\

dim strComputer, strThisComputer
Dim objShell
Dim objFSO,objFile
Dim objNetwork
dim taskcount
dim checkarray(100,100)
dim checkarrayz(100,100)

Const ForReading = 1
Const ForWriting = 2

Dim oShell : Set oShell = CreateObject("Wscript.Shell")
Set objShell = CreateObject("WScript.Shell")
Set objFSO=CreateObject("Scripting.FileSystemObject")

strTempDir=objShell.ExpandEnvironmentStrings("%temp%")
strTempFile="MJP-Tasks.csv"
strCSV=strTempDir & "\" & strTempFile

forceUseCScript

'Find this machine's name to use as an initial value. 
 Set objNetwork=CreateObject("WScript.Network")
 strThisComputer=objNetwork.ComputerName
 
'Prompt for a computer name
strcomputer=inputbox("Enter machine to monitor Tasks")
if strComputer = "" then strComputer = strThisComputer

'Prompt for monitoring time in hours
strhours=inputbox("Enter number of hours you would like to monitor "&strcomputer&vbcrlf&vbcrlf&"Enter hours as a whole number only")
timerS=(now)
timerF=DateAdd("h",strhours,now)

wscript.echo "Script started at "&timerS&" Will monitor till "&timerF

ReadTasks

BaselineTasks

do 
  wscript.sleep(10000) 'check every 10 seconds 
  CompareTasks
loop until (now) > timerF

wscript.echo "Finished monitoring Tasks "&now

'----------------------------------------------------------------------

Sub ReadTasks

' Excecute command - Query computer for scheduled task information
 strCMD="cmd /c c:\windows\system32\Schtasks.exe /S " & strComputer & " /query /fo csv /NH /v > " & strCSV
 objShell.Run strCmd,0,True

' only run if file exists size is greater than 0
 if objFSO.FileExists(strCSV) then
    Set objFile = objFSO.OpenTextFile(strCSV, ForReading)

' Clean up file - remove blank lines at top
    Do Until objFile.AtEndOfStream
       strLine = objFile.Readline
       strLine = Trim(strLine)
       If Len(strLine) > 0 Then
          strNewContents = strNewContents & strLine & vbCrLf
       End If
    Loop
    objFile.Close
    Set objFile = objFSO.OpenTextFile(strCSV, ForWriting)
    objFile.Write strNewContents
    objFile.Close

' Count the number of lines in file (equals the number of tasks) 
    Set objFile = objFSO.OpenTextFile(strCSV, ForReading)
    Do While Not objFile.AtEndOfStream
       strLine = objFile.ReadLine
       If strLine = "INFO: There are no scheduled tasks present in the system." then
          wscript.echo strLine
          wscript.quit
       end if
       readCSVfile = Split(strLine , chr(34)&","&chr(34))
       TaskCountx=Taskcountx + 1                       
    Loop
    objFile.Close

'wscript.echo  "Number of Tasks is "&TaskCountx
    TaskCount = TaskCountx
 End if

for TaskNo=1 to TaskCount

'Read a specific line of the csv file and populate values for table - note there is one task on each line of the file.
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objTextFile = objFSO.OpenTextFile(strCSV, ForReading)

strNextLine = objTextFile.ReadLine

If strNextLine = "INFO: There are no scheduled tasks present in the system." then
       wscript.echo  "There are no scheduled tasks present on the computer " & UCASE(strComputer)
       wscript.quit
    end if

readCSVfile = Split(strNextLine , chr(34)&","&chr(34))
 
    On error resume next
    for z=0 to 26
       checkarray(taskNo,z) = Replace(readCSVfile(z), chr(34), "")
    next
    on error goto 0

objTextFile.Close

end sub

'----------------------------------------------------------------------

sub BaselineTasks

for x=1 to TaskCount
  for y=0 to 26
     checkarrayZ(x,y) = checkarray(x,y) 
  next
Next

wscript.echo ""
wscript.echo "New baseline of tasks on "&strComputer&" has been made. "&now
wscript.echo ""

end sub

'----------------------------------------------------------------------

sub CompareTasks

ReadTasks

for xx=1 to TaskCount
  for yy=0 to 26
     
     if checkarrayZ(xx,yy) <> checkarray(xx,yy) then

'***to monitor specific item like task status, change statement to *** if checkarrayZ(xx,3) <> checkarray(xx,3) then ***

'****Run your alert code here****
         changed = "yes"
     else
        'wscript.echo  "same"
     end if
  Next
next

if changed = "yes" then 
wscript.echo  "Scheduled tasks on "&strcomputer&" have changed. "&now
BaselineTasks
end if

End Sub

'----------------------------------------------------------------------

Sub forceUseCScript()
  If Not WScript.FullName = WScript.Path & "\cscript.exe" Then
     oShell.Popup "Launched using wscript. Relaunching...",3,"WSCRIPT"
     oShell.Run "cmd.exe /k " & WScript.Path & "\cscript.exe //NOLOGO " & Chr(34) & WScript.scriptFullName & Chr(34),1,False
     WScript.Quit 0
  End If
End Sub

'----------------------------------------------------------------------

(in reply to Meg)