AD Disabled Users

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

AD Disabled Users

Logged in as: Guest

arrSession:exec spGetSession 2,16,52046

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> AD Disabled Users
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

AD Disabled Users - 9/20/2007 2:53:28 AM

4scriptmoni

Posts: 192
Score: 0
Joined: 5/3/2007
Status: offline

This script will get all Disabled users under specific OU, and will output to one single txt.
It runs quite fast. i ran on OU with 530K users in less then 4min.

'Get users created each day and put in TXT
'count OU users save to log, compare to logcou.txt (from yesterday) and print result to TXT
'Author Felipe Ferreira fel.h2o(a)gmail.com
'Date 20/09/2007
' ---------------------------------------------------------------------------
'Option Explicit
On Error Resume next

'DECLARE VARS
Dim intCount,intcountd
Dim strQuery,strFilter,objConnection,objCommand
Dim outputfile, oFile
Const ForWriting = 2, ForReading = 1, ForAppending = 8
Dim strScriptFile : strScriptFile = WScript.ScriptFullname
Dim strScriptPath : strScriptPath = Left(strScriptFile, Len(strScriptFile) - Len(WScript.Scriptname)) 'used to define the path from where the script file is located
Dim t1 : t1 = Timer
intCount = 0
'@@@@@@@@@@@@@@@@@@ EDIT @@@@@@@@@@@@@@@@@
Dim strOU : strOU="ENTEROU"
'@@@@@@@@@@@@@@@@@@ EDIT @@@@@@@@@@@@@@@@@

outputfile= strScriptPath & "disabled_"& strOU & ".txt"

'LOG FILE
Dim oFSO : Set oFSO = CreateObject("Scripting.FilesyStemObject")
Set ofile = oFso.OpenTextFile(outputfile, ForAppending, TRUE)

Dim objRecordSet 
' Use ADO to search the domain for all users.
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOOBject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection

strFilter = "(&(objectCategory=user))"
strQuery = "<LDAP://OU="& strOU &",DC=DOMAIN,DC=local>;" & strFilter &_
 "; userAccountControl,mail;subtree"

wscript.echo strquery

objCommand.CommandText = strQuery
objCommand.Properties("Page Size") = 1000   '100 works fine, 1000 for over 1 million users
objCommand.Properties("Timeout") = 90       '60 is OK
objCommand.Properties("Cache Results") = False
if err <> 0 then
   wscript.echo "Error " & err.description
end if

Set objRecordSet = objCommand.Execute
Do Until objRecordSet.EOF
    intCount = intCount + 1
   accountName = objRecordSet.Fields("mail")
   accountID = objRecordSet.Fields("userAccountControl")
   wscript.stdout.write(".")
   if accountID = 514 or accountID = 66050 or accountID = 66082 then
               Wscript.Echo vbCrlf & accountName & " DISABLED"
               ofile.writeline accountName 
   intcountd = intcountd + 1
   end if    
   objRecordSet.MoveNext
Loop

' Clean up.
ofile.close
objConnection.Close
Set oFile = Nothing
Set oFSO = Nothing
Set objConnection = Nothing
Set objCommand = Nothing
Set objRecordSet = Nothing

RunTime = Timer  - t1
RunTime = Left(RunTime, 4)
wscript.echo vbCrlf &  vbCrlf & "OU: " & strOU &" Total Users: " & intCount 
wscript.echo  "Total Users Disabled: " & intCountD 
wscript.echo "Script Runtime: " & RunTime & "sec."
Wscript.Echo "Done"
wscript.quit

_____________________________

Enterprise Microsoft Scripts
Exchange, Login/Logout Monitor,TS, Monitoring, Security, AD, etc...
http://www.felipeferreira.net

Post #: 1

RE: AD Default Mbx Size - 10/29/2007 10:53:45 PM

4scriptmoni

Posts: 192
Score: 0
Joined: 5/3/2007
Status: offline

To find all Mailbox Set with Default Size and get an output of their UPN (emaiL)
The code is simillar (improved from the last post)

'Get All Mbx Default Size from Specified OU
'Author Felipe Ferreira fel.h2o(a)gmail.com
'Date 20/09/2007
' ---------------------------------------------------------------------------
Option Explicit

'DECLARE
Dim t1 : t1 = Timer
Const ForWriting = 2, ForReading = 1, ForAppending = 8
Dim intCount,intcountd
Dim accountDefaultLimit,accountName
Dim strQuery,strFilter,objConnection,objCommand
Dim outputfile, oFile
Dim RunTime,Location,rootd

'@@@@@@@@@@@@@@@@@@ EDIT @@@@@@@@@@@@@@@@@
Dim strOU : strOU="ENTER OU HERE"  'OU where to search
Dim intScope : intScope = 1     'SearchScope parameter.  0 = this exact key, 1 = one level down, 2 = entire subtree.
'@@@@@@@@@@@@@@@@@@ EDIT @@@@@@@@@@@@@@@@@

rootd =  GetObject("LDAP://RootDSE").Get("DefaultNamingContext")
location = "OU="& strOU & ","& rootd
wscript.echo location
Dim strScriptFile : strScriptFile = WScript.ScriptFullname
Dim strScriptPath : strScriptPath = Left(strScriptFile, Len(strScriptFile) - Len(WScript.Scriptname))

intCount = 0
outputfile= strScriptPath & strOU & "_MBX_DefaultSizeLimit.txt"

'LOG FILE
Dim oFSO : Set oFSO = CreateObject("Scripting.FilesyStemObject")
Set ofile = oFso.OpenTextFile(outputfile, ForAppending, TRUE)

Dim objRecordSet

' Use ADO to search the domain for all users.
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOOBject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection

strFilter = "(&(objectCategory=user))"
strQuery = "<LDAP://"& location & ">;" & strFilter &_
 "; mDBUseDefaults,mail"
wscript.echo strquery

objCommand.CommandText = strQuery
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 90 
objCommand.Properties("Searchscope") = intScope
objCommand.Properties("Cache Results") = False

Set objRecordSet = objCommand.Execute
On error Resume Next 
Do Until objRecordSet.EOF    
   intCount = intCount + 1
  accountName = objRecordSet.Fields("mail")
  accountDefaultLimit = objRecordSet.Fields("mDBUseDefaults")
  wscript.stdout.write(".")
  if accountDefaultLimit = True then
              Wscript.Echo vbCrlf & accountName & " Has Default Mbx Size" & vbCrlf 
              ofile.writeline accountName 
              intcountd = intcountd + 1
      
  end if    
  Wscript.StdOut.Write(".")        
  objRecordSet.MoveNext
Loop

RunTime = Timer  - t1
RunTime = Left(RunTime, 4)

wscript.echo vbCrlf &  vbCrlf & "OU: " & strOU &" Total Users: " & intCount 
wscript.echo  "Total Users MBX Default Limit: " & intCountD 
wscript.echo "Script Runtime: " & RunTime & "sec."

' Clean up.
objConnection.Close
Set oFile = Nothing
Set oFSO = Nothing
Set objConnection = Nothing
Set objCommand = Nothing
Set objRecordSet = Nothing
ofile.close
Wscript.Echo "Done"
wscript.quit

_____________________________

Enterprise Microsoft Scripts
Exchange, Login/Logout Monitor,TS, Monitoring, Security, AD, etc...
http://www.felipeferreira.net

(in reply to 4scriptmoni)