installing network printers

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

installing network printers

Logged in as: Guest

arrSession:exec spGetSession 2,16,52268

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> installing network printers
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

installing network printers - 9/27/2007 5:08:05 AM

jftuga

Posts: 1
Score: 0
Joined: 9/27/2007
From: Athens, GA
Status: offline

I just discovered this forum today and it looks wonderful. So I thought I would share a script that I recently wrote. Given a list of network printers and a print server, this script will install any network printers that are not already installed and skip the ones that are. I imagine this running from a logon script for an OU.

-John

' install_network_printers.vbs
' -John Taylor
' Sept-26-2007
'
' to view your network's printers, from the cmd line:
' net view \\example_server (use the name of your printer server)
'
' change these 2 variables: print_svr, net_printer_list

print_svr = "\\pserver1"
net_printer_list = Array( "HR Laser Printer", "IT Color", _
       "Admin Color", _
       "Division 1 Duplex", "Division 2 Color" )

' should not have to modify anything below this line

' create a list of printers containing their fully quailfied unc name in all lower case
' add them to a vb dictionary
set unc_printer_dict = CreateObject("Scripting.Dictionary")
unc_printer_list = net_printer_list
print_svr = lcase(print_svr)
for i = 0 to ubound(unc_printer_list)
       unc_printer_list(i) = print_svr & "\" & lcase(unc_printer_list(i))
       unc_printer_dict.add unc_printer_list(i), i
next

wscript.echo "Network Printer List:"
for each ptr in unc_printer_list
       wscript.echo vbtab & ptr
next
wscript.echo

' get a list of currently installed printers on the local system
Set objNetwork = CreateObject("WScript.Network")
Set objSysInfo = CreateObject("ADSystemInfo")
strName = objSysInfo.ComputerName

arrComputerName = Split(strName, ",")
arrOU = Split(arrComputerName(1), "=")
strComputerOU = arrOU(1)

Set objWMIService = GetObject("winmgmts:\\" & "UHC1500" & "\root\cimv2")
Set colPrinters = objWMIService.ExecQuery _
   ("Select * From Win32_Printer Where Local = FALSE")

' compare this list of local installed printers to the network printers
' listed in the unc_printer_list array
' if the printer is already installed, do nothing
' otherwise install the printer
wscript.echo "Already installed:"
For Each objPrinter in colPrinters
       local_ptr = lcase(objPrinter.Name)
       if unc_printer_dict.exists(local_ptr) then
               wscript.echo vbtab & local_ptr
               unc_printer_dict.remove(local_ptr)
       end if
next
wscript.echo

' install any printers not alreay installed
' hopefully, the printer drivers are already installed on the system
printers_to_install = unc_printer_dict.keys
wscript.echo "Installing:"
for each ptr in printers_to_install
       wscript.echo vbtab & ptr
       objNetwork.AddWindowsPrinterConnection ptr
next
wscript.echo