Set NIC Speed to Auto on popular NICs

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Set NIC Speed to Auto on popular NICs

Logged in as: Guest

arrSession:exec spGetSession 2,16,52708

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Set NIC Speed to Auto on popular NICs
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Set NIC Speed to Auto on popular NICs - 10/15/2007 11:44:04 PM

ginolard

Posts: 1044
Score: 21
Joined: 8/10/2005
Status: offline

We are in the process of upgrading our LAN to 100 mb/s. As a result the network team have asked me to ensure that the NICs on all client machines are set to "Auto" for the speed and duplex settings.

Given that we have several different NICs in existence, this proved tricky. Anyway, this is the script I've been using.

Option Explicit
Const HKEY_LOCAL_MACHINE = &H80000002
Const ForReading = 1

CheckAllNICS

Sub CheckAllNICS
  Dim objFSO : Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
  Dim InputFile, ArrayFile, i
  InputFile=TrimWS(objFSO.OpenTextFile("c:\temp\input.txt",ForReading).ReadAll)
    
  ArrayFile = Split(Trimws(InputFile),vbcrlf)
    
  For i = 0 To UBound(Arrayfile)
      If IsOnline(Arrayfile(i)) Then
          IdentifyNIC(Arrayfile(i))
      Else
          WScript.Echo ArrayFile(i) & ",OFFLINE" 
      End If
  Next
End Sub

Sub IdentifyNIC(strComputer)
  Dim objReg
  Dim blnNicFound
  Dim strKeyPath,arrSubKeys,subkey,strValue
  On Error Resume Next
  blnNicFound = True
  Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
  If Err Then 
      WScript.Echo strComputer & ",ERROR READING REGISTRY"
      Exit Sub
  Else
      strKeyPath = "System\Currentcontrolset\Control\Class\{4D36E972-E325-11CE-BFC1-08002be10318}"
      objReg.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubKeys

For Each subkey In arrSubKeys
          
          objReg.GetStringvalue HKEY_LOCAL_MACHINE, strKeyPath & "\" & subkey,"DriverDesc", strValue
          Select Case strValue
              Case "3Com EtherLink XL 10/100 PCI TX NIC (3C905B-TX)"
                  WScript.Echo "** CHECK DUPLEX SETTING MANUALLY **"
                  Exit Sub
              Case "Broadcom NetXtreme Gigabit Ethernet"
                  CheckDuplexValue strKeyPath & "\" & subkey, "RequestedMediaType", strComputer, strValue
                  Exit Sub
              Case "HP NC7781 Gigabit Server Adapter"
                  WScript.Echo "** CHECK DUPLEX SETTING MANUALLY **"
                  Exit Sub
              Case "HP NC7782 Gigabit Server Adapter"
                  WScript.Echo "** CHECK DUPLEX SETTING MANUALLY **"
                  Exit Sub
              Case "Intel(R) 82540EM Based Network Connection", _
                   "Intel(R) PRO/100 VE Network Connection", _
                   "Intel(R) PRO/100 VM Network Connection", _
                   "Intel(R) PRO/1000 EB Network Connection with I/O Acceleration", _
                   "Intel(R) PRO/1000 MT Network Connection"
                   CheckDuplexValue strKeyPath & "\" & subkey, "SpeedDuplex", strComputer, strValue
                   Exit Sub
              Case "Marvell Yukon 88E8055 PCI-E Gigabit Ethernet Controller"
                  CheckDuplexValue strKeyPath & "\" & subkey, "ConnectionType_A", strComputer, strValue
                  Exit Sub
              Case "NVIDIA nForce Networking Controller"
                  CheckDuplexValue strKeyPath & "\" & subkey, "ForceSpeedDpx", strComputer, strValue
                  Exit Sub
              Case "Realtek RTL8139C+ Fast Ethernet NIC"
                  WScript.Echo "** CHECK DUPLEX SETTING MANUALLY **"
                  Exit Sub
              Case Else
                  blnNicFound = False
          End Select
      Next
      
      If Not blnNICFound Then
          WScript.Echo "Unknown NIC on " & strComputer
      End If
      
  End If
End Sub

Sub CheckDuplexValue (strDuplexSettingKeyPath,strDuplexSettingSubKey,strComputer,NICType)
  Dim strValue
  Dim objReg : Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
  objReg.GetStringValue HKEY_LOCAL_MACHINE, strDuplexSettingKeyPath, strDuplexSettingSubKey, strValue
  If strValue <> 0 Then 
      objReg.SetStringValue HKEY_LOCAL_MACHINE, strDuplexSettingKeyPath, strDuplexSettingSubKey, "0"
      objReg.GetStringValue HKEY_LOCAL_MACHINE, strDuplexSettingKeyPath, strDuplexSettingSubKey, strValue
      WScript.Echo strComputer & ","  & NICType & "," & strDuplexSettingSubKey & "," & strValue
  End If
End Sub

Private Function trimWS(sTxt)
  Dim oRE : Set oRE = New RegExp
  oRE.Pattern =  "(^\s+)|(\s+$)"
  oRE.Global  = True
  trimWS      = oRE.Replace( sTxt, "" )
End Function

Function IsOnline(PCName)
  Dim objItem
  Dim objPing : Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._
      ExecQuery("select * from Win32_PingStatus where address = '" & PCName & "'")
  
  For Each objItem in objPing
      If IsNull(objItem.ReplySize) Then 
          IsOnline = False
      Else
          IsOnline = True
      End If
  Next

End Function

It reads in a list of machines from a c:\temp\input.txt although you could just as easily get a list of machines from AD and parse that instead. It should handle most popular NICs although there might be some weird and wonderful ones out there that it can't handle. If so, you will need to find out the relevant key that sets the "Auto" setting and also the name of the NIC under System\Currentcontrolset\Control\Class\{4D36E972-E325-11CE-BFC1-08002be10318} and add an appropriate Case statement.

Oh, in case you were wondering why I do this

It's just to check that the value was REALLY changed. Perhaps a bit of overkill but I want to 100% certain it's worked ;)

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm