Script Demonstrating DIV tags in HTA

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Script Demonstrating DIV tags in HTA

Logged in as: Guest

arrSession:exec spGetSession 2,16,53534

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Script Demonstrating DIV tags in HTA
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Script Demonstrating DIV tags in HTA - 11/13/2007 11:50:57 PM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

My last script used DIV tags and I am impressed with the extra flexibility I now have over the design of my scripts.

This example script is heavily commented so I am sure you will find it useful if you are interested in implementing features like this into your scripts.

-Create a new file on your computer called DIVHTA.HTA and paste the attached code into it.

-Run DIVHTA.HTA

-Usage instructions are displayed in Program.

Enjoy

<html>
<head>
<title>DIVHTA</title>

<SCRIPT LANGUAGE="VBScript">
' Set window dimentions loaded here to prevent flicker, method (c) M. Harris
window.resizeto 750,400
</SCRIPT>

<HTA:APPLICATION 
ID="MJP"
APPLICATIONNAME="DIVHTA"
SCROLL="yes"
SINGLEINSTANCE="yes"
>

<style>
body,td a {font-family:Tahoma, Veranda, Arial; font-size:16px; text-decoration:none; color:black;} 
H1 { font-family:Tahoma, Veranda, Arial; font-size:20px; color : blue; }
a:link { color : yellow; background : transparent ;   text-decoration: underline ; font-size:12px;} 
a:visited { color : yellow; background : transparent ;   text-decoration: none ; font-size:12px;} 
a:Hover { color : red; background : transparent ;   text-decoration: none ; font-size:12px;} 
</style>

<SCRIPT LANGUAGE="VBScript">

'--------------------------------------------------------------------------------

Sub Window_Onload 
' This sub runs when the application starts.

' Run SplashScreen Subroutine     
SplashScreen
End Sub

'--------------------------------------------------------------------------------

Sub SplashScreen 
' Show the splash screen and open the HTA on the Main page
    
' Select a small image file from your windows or winnt directory
Const sBGBmp = "url(c:\windows\Prairie Wind.bmp)"

Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none" 
Splash.Style.Display = "inline"
Splash.Style.BackgroundImage = sBGBmp

' wait 4 seconds
sleep 4

Main.Style.Display = "inline" 
Splash.Style.Display = "none"
run_button1.disabled = true
End Sub

'--------------------------------------------------------------------------------

Sub Home
' This sub runs when the Home button is pressed

' Display HTML for Home Page only
Main.Style.Display = "inline" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button1.disabled = true
run_button2.disabled = false
run_button3.disabled = false
run_button4.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageOne
' This sub runs when the Page1 button is pressed

' Display HTML for Page1 only
Main.Style.Display = "none" 
PgOne.Style.Display = "inline" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button5.disabled = false
run_button6.disabled = true
run_button7.disabled = false
run_button8.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageTwo
' This sub runs when the Page2 button is pressed

' Display HTML for Page2 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "inline" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button9.disabled = false
run_button10.disabled = false
run_button11.disabled = true
run_button12.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageThree
' This sub runs when the Page3 button is pressed

' Display HTML for Page3 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "inline"

' Grey out button of currently displayed page
run_button13.disabled = false
run_button14.disabled = false
run_button15.disabled = false
run_button16.disabled = true
End Sub

'--------------------------------------------------------------------------------

Sub MyMessage
' This sub runs when the "My Message" button on page2 is pressed

msgbox "I hope this example script is useful to you in demonstrating the flexibility and power"&vbcrlf&"of using DIV code in your HTA code"
End Sub

'--------------------------------------------------------------------------------

Sub DClock
' This sub runs when the Clock button on page3 is pressed

' Activate DIV code ShowClock
ShowClock.Style.Display = "inline"

' Display the time in the HTA (cool-updated every second)
iTimerID = window.setInterval("HTAClock", 1000)
End Sub

' This needs to go into a seperate sub to stop resources getting gobbled. 
sub HTAClock

' Display the current system time
Dtime.InnerHTML = time
end sub

'--------------------------------------------------------------------------------

Sub Sleep(strSeconds) 
' sub to make the script pause for x seconds

strCmd = "%COMSPEC% /c ping -n " & strSeconds & " 127.0.0.1>nul" 
Set objShell=CreateObject("Wscript.shell") 
objShell.Run strCmd,0,1 
End Sub

'--------------------------------------------------------------------------------

sub DIVHTAClose
' when the close button is pressed on Page3 this code runs and closes the HTA

'display my splash screen
PgThree.Style.Display = "none" 
Splash.Style.Display = "inline"

' wait 2 seconds
sleep 2

' close HTA
self.close
end sub

'-------------------------------------------------------------------------------- 
</SCRIPT>

</head>

<body>

<DIV id="Splash" STYLE="Background-color:184a5a;Height:200;Width:400;Border:0.4mm solid black;position:relative;top:60;left:175;"> 
<br><br> 
<center> 
<font face="arial" color=White size=5><b><i> DIVHTA </i></b></font> 
<br> 
<a href="http://www.painterinfo.com/php2bb/viewtopic.php?t=518">By MJP 2007</a> 
<br><br> 
<font color=white>Example HTA to demonstrate use of DIV  </font>
</center> 
</DIV>

<DIV id="Main" STYLE="display:none;position:absolute"> 
<input id=runbutton1  class="button" type="button" value="Home" name="run_button1"  onClick="Home">
<input id=runbutton2  class="button" type="button" value="Page1" name="run_button2"  onClick="PageOne">
<input id=runbutton3  class="button" type="button" value="Page2" name="run_button3"  onClick="PageTwo">
<input id=runbutton4  class="button" type="button" value="Page3" name="run_button4"  onClick="PageThree">
<BR><BR>
<H1>Main Page</H1>
<br>
Open  <input id=runbutton17  class="button" type="button" value="Splash" name="run_button17"  onClick="SplashScreen"> Window
</DIV>

<DIV id="PgOne" STYLE="display:none;position:absolute"> 
<input id=runbutton5  class="button" type="button" value="Home" name="run_button5"  onClick="Home">
<input id=runbutton6  class="button" type="button" value="Page1" name="run_button6"  onClick="PageOne">
<input id=runbutton7  class="button" type="button" value="Page2" name="run_button7"  onClick="PageTwo">
<input id=runbutton8  class="button" type="button" value="Page3" name="run_button8"  onClick="PageThree">
<BR><BR>
<H1>Page 1</H1>
<br>
Simple Message Box <input id=runbutton20  class="button" type="button" value="My Message" name="run_button20"  onClick="MyMessage">
</DIV>

<DIV id="PgTwo" STYLE="display:none;position:absolute"> 
<input id=runbutton9  class="button" type="button" value="Home" name="run_button9"  onClick="Home">
<input id=runbutton10  class="button" type="button" value="Page1" name="run_button10"  onClick="PageOne">
<input id=runbutton11  class="button" type="button" value="Page2" name="run_button11"  onClick="PageTwo">
<input id=runbutton12  class="button" type="button" value="Page3" name="run_button12"  onClick="PageThree">
<BR><BR>
<H1>Page 2</H1>
<br>
Show Time <input id=runbutton19  class="button" type="button" value="Clock" name="run_button19"  onClick="Dclock">
</DIV>

<DIV id="PgThree" STYLE="display:none;position:absolute"> 
<input id=runbutton13  class="button" type="button" value="Home" name="run_button13"  onClick="Home">
<input id=runbutton14  class="button" type="button" value="Page1" name="run_button14"  onClick="PageOne">
<input id=runbutton15  class="button" type="button" value="Page2" name="run_button15"  onClick="PageTwo">
<input id=runbutton16  class="button" type="button" value="Page3" name="run_button16"  onClick="PageThree">
<BR><BR>
<H1>Page 3</H1>
<br>
Close Window <input id=runbutton18  class="button" type="button" value="Close" name="run_button18"  onClick="DIVHTAClose">
</DIV>

<DIV id="Showclock" STYLE="display:none;position:relative;top:5;left:270;"> 
<font color=red><span id=Dtime>MJP's Clock</span></font>
</DIV>

</body> 
</html>

< Message edited by Meg -- 11/14/2007 11:40:46 PM >

Revisions: 7 | Post #: 1

RE: Script Demonstrating DIV tags in HTA - 11/14/2007 5:00:29 AM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi Meg,

as dm_4ever said regarding your GoogleMap .hta: very nice and interesting code.

Just one nit to pick:

   The script section should be part of the head.

two suggestions:

   By moving the .resizeto code (in a tag of its own) before the hta tag, you could
   avoid flickering (this method is (c) M. Harris)

   Make the ref to c:\windows\Prairie Wind.bmp a (configurable) constant; that will
   help foreigners to switch to c:\winnt\Pr�riewind.bmp

and one typo (?)

<a href="By'>http://www.painterinfo.com/php2bb/">By MJP 2007</a>
==>
<a href="http://www.painterinfo.com/php2bb/">By MJP 2007</a>

Thanks for the inspiring sample!

ehvbs

(in reply to Meg)

Post #: 2

RE: Script Demonstrating DIV tags in HTA - 11/14/2007 9:58:03 AM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Thanks for the feedback. I really appreciate that.

Your comments have really lifted the script.
I have fixed those things you mentioned but am stumped on how to make that image a configurable variable.

I can't use <span> because it is within a DIV tag and I even tried the asp trick of <%response.write MyImg%>
I could have tried making the entire DIV tag a span but that makes the script harder to understand etc.

< Message edited by Meg -- 11/14/2007 9:40:59 PM >

(in reply to ehvbs)

Revisions: 1 | Post #: 3

RE: Script Demonstrating DIV tags in HTA - 11/14/2007 11:25:19 PM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi Meg,

defining

   Const sBGBmp = "url(c:\winnt\Pr�rieWind.bmp)"

at the top (first script section) and extending your method of run time style manipulation

   Splash.Style.Display = "inline"
   Splash.Style.BackgroundImage = sBGBmp

worked for me (W2K, IE 6).

Regards (and good luck with IE 7 and Vista)

ehvbs

(in reply to Meg)

Post #: 4

RE: Script Demonstrating DIV tags in HTA - 11/14/2007 11:54:57 PM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Hi ehvbs,

That works well and also hints at other .style. features being able to be manipulated from script, which is good.

Thanks.

(in reply to ehvbs)

Post #: 5

RE: Script Demonstrating DIV tags in HTA - 11/16/2007 12:30:49 AM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

Very nice. Where were you on Monday when I was trying to figure out something similiar? But this is a nicer way than what I was doing, will see about using some of your methods.

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.

(in reply to Meg)

Post #: 6

RE: Script Demonstrating DIV tags in HTA - 11/16/2007 1:59:35 AM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

Started playing with your code to understand it better to enable me to add features to my HTA and I started wondering if the Runbuttonx's were a little redundunt. So, I took a look at trying to do them a little different and this is what I came up with .

Add this section above the Splash Div and Remove all the button groupings in the divs.

Add this Sub

In the Subs, replace any 4 grouping
run_button13.disabled = false
run_button14.disabled = false
run_button15.disabled = false
run_button16.disabled = true
With

SetButton(x) where x is the button you want to disable.

Here is the full code. Once again, excellent job.

<html>
<head>
<title>DIVHTA</title>

<SCRIPT LANGUAGE="VBScript">
' Set window dimentions loaded here to prevent flicker, method (c) M. Harris
window.resizeto 750,400
</SCRIPT>

<HTA:APPLICATION 
ID="MJP"
APPLICATIONNAME="DIVHTA"
SCROLL="yes"
SINGLEINSTANCE="yes"
>

<SCRIPT LANGUAGE="VBScript">

'--------------------------------------------------------------------------------

Sub Window_Onload 
' This sub runs when the application starts.

' Run SplashScreen Subroutine     
SplashScreen
End Sub

'--------------------------------------------------------------------------------

Sub SplashScreen 
' Show the splash screen and open the HTA on the Main page
   
' Select a small image file from your windows or winnt directory
Const sBGBmp = "url(c:\windows\Prairie Wind.bmp)"

Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none" 
Buttons.Style.Display = "none" 
Splash.Style.Display = "inline"
Splash.Style.BackgroundImage = sBGBmp

' wait 4 seconds
sleep 4

Main.Style.Display = "inline" 
Buttons.Style.Display = "inline" 
Splash.Style.Display = "none"
' run_button1.disabled = True
SetButton(1)
End Sub

'--------------------------------------------------------------------------------

Sub SetButton(btn)
Dim disabled(4)
 For i=1 To 4
   disabled (i) = False'Set all buttons to display
 Next
 disabled (btn) = True 'Disable the appropriate button

Run_button1.disabled=disabled(1)
 Run_button2.disabled=disabled(2)
 Run_button3.disabled=disabled(3)
 Run_button4.disabled=disabled(4)
End Sub

Sub Home
' This sub runs when the Home button is pressed

' Display HTML for Home Page only
Main.Style.Display = "inline" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
SetButton(1)
End Sub

'--------------------------------------------------------------------------------

Sub PageOne
' This sub runs when the Page1 button is pressed

' Display HTML for Page1 only
Main.Style.Display = "none" 
PgOne.Style.Display = "inline" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
SetButton(2)
End Sub

'--------------------------------------------------------------------------------

Sub PageTwo
' This sub runs when the Page2 button is pressed

' Display HTML for Page2 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "inline" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
SetButton(3)
End Sub

'--------------------------------------------------------------------------------

Sub PageThree
' This sub runs when the Page3 button is pressed

' Display HTML for Page3 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "inline"

' Grey out button of currently displayed page
SetButton(4)
End Sub