Vista Cscript For Launching Games

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Vista Cscript For Launching Games

Logged in as: Guest

arrSession:exec spGetSession 2,16,54688

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Vista Cscript For Launching Games
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Vista Cscript For Launching Games - 12/23/2007 9:27:05 AM

techie007

Posts: 5
Score: 0
Joined: 12/11/2007
Status: offline

This is the result of a few day long hack fest. :)

It's specifically intended for Vista, so it may miss stuff on other Windows versions.

It shuts down as many services and processes as it can and then prompts for a game to launch.

Frees up 200-300MB of RAM on my Vista machine, and turns off about 20 processes.

Makes no permanent changes, so you can just reboot at any time to be back to normal.

' VGL.vbs (Vista Game Launcher)  v.42a
' Kills as much of vista as possible so that the most
' resources are available to a single program (ie: a game)
' ----------------------------------------------------------------------' 
' Run via ELEVATED CMD.EXE: "cscript vgl.vbs"
' Reboot to restore!
' Hacked togeather by techie007  
' Big Ups, Props and Thanks to the Internet.
' ----------------------------------------------------------------------' 
' Changes:
' (Dec. '07)
' .42 - Release
' .42a - Ensured varible cleansing in loop (avoids strAppPath double-up)
'      - Added some error checking
' .42b - Rearranged and massaged code for readability.
' ----------------------------------------------------------------------' 
Option Explicit
Dim objWMIService, objItem, objService, objService2, objProcess, objShell
Dim objFileSystem
Dim colListOfServices, colListOfRunningServices, ReturnCode, i, intLoops
Dim strServiceList, strExitOpt, strAppPath, strProgName
Dim arrServicesToKeep(40), arrProcessesToKeep(22), arrGames(3,2), arrPath
'<-----------------------------Arrays and Variables------------------------->
' Number of Decendant shutdown loops
intLoops = 2
' 2D Array of 3 games in pick-list (Display Name, Execution Path)
arrGames(0,0) = "Gears Of War"
arrGames(0,1) = "D:\Games\Gears of War\Binaries\Startup.exe"
arrGames(1,0) = "The Movies (Stunts & Effects)"
arrGames(1,1) = "D:\Games\The Movies\MoviesSE.exe"
arrGames(2,0) = "Guitar Hero III"
arrGames(2,1) = "D:\Games\Guitar Hero III\GH3.exe"
' Services to keep (display name)
arrServicesToKeep(0) = "dummy" ' for fExsits' sake
arrServicesToKeep(1) = "COM+ Event System"
arrServicesToKeep(2) = "Computer Browser"
arrServicesToKeep(3) = "Cryptographic Services"
arrServicesToKeep(4) = "DCOM Server Process Launcher"
arrServicesToKeep(5) = "DHCP Client" ' Netowrking
arrServicesToKeep(6) = "DNS Client" ' Netowrking
arrServicesToKeep(7) = "Group Policy Client"
arrServicesToKeep(8) = "Multimedia Class Scheduler"
arrServicesToKeep(9) = "Network List Service" ' Netowrking
arrServicesToKeep(10) = "Network Location Awareness" ' Netowrking
arrServicesToKeep(11) = "Network Store Interface Service" ' Netowrking
arrServicesToKeep(12) = "Plug and Play"
arrServicesToKeep(13) = "Remote Procedure Call (RPC)"
arrServicesToKeep(14) = "Secondary Logon"
arrServicesToKeep(15) = "Security Accounts Manager"
arrServicesToKeep(16) = "Server"
arrServicesToKeep(17) = "Software Licensing"
arrServicesToKeep(18) = "Superfetch"
arrServicesToKeep(19) = "System Event Notification Service"
arrServicesToKeep(20) = "Task Scheduler"
arrServicesToKeep(21) = "TCP/IP NetBIOS Helper" ' Netowrking
arrServicesToKeep(22) = "User Profile Service"
arrServicesToKeep(23) = "Windows Audio"
arrServicesToKeep(24) = "Windows Audio Endpoint Builder"
arrServicesToKeep(25) = "Windows Event Log"
arrServicesToKeep(26) = "Windows Management Instrumentation"
arrServicesToKeep(27) = "Windows Time"
arrServicesToKeep(28) = "Workstation"
arrServicesToKeep(29) = "Wired AutoConfig" ' Netowrking
arrServicesToKeep(30) = "WLAN AutoConfig" ' Networking
arrServicesToKeep(31) = "Intel(R) Matrix Storage Event Monitor"
arrServicesToKeep(32) = "CNG Key Isolation" 'Networking
arrServicesToKeep(33) = "Windows Driver Foundation - User-mode Driver Framework"
arrServicesToKeep(34) = "Network Connections" 'Networking
arrServicesToKeep(35) = "Shell Hardware Detection"
arrServicesToKeep(36) = "Extensible Authentication Protocol" ' Networking
arrServicesToKeep(37) = "Application Information"
arrServicesToKeep(38) = "Remote Access Connection Manager" 'Can't Turn it off (suspect NIC driver control)
arrServicesToKeep(39) = "Telephony" 'Required for "Remote Access Connection Manager", see above.
' Processes to keep (image name)
arrProcessesToKeep(0) = "dummy" ' for fExsits' sake
arrProcessesToKeep(1) = "System Idle Process"
arrProcessesToKeep(2) = "System"
arrProcessesToKeep(3) = "smss.exe"
arrProcessesToKeep(4) = "csrss.exe"
arrProcessesToKeep(5) = "wininit.exe"
arrProcessesToKeep(6) = "services.exe"
arrProcessesToKeep(7) = "lsass.exe"
arrProcessesToKeep(8) = "lsm.exe"
arrProcessesToKeep(9) = "winlogon.exe"
arrProcessesToKeep(10) = "svchost.exe"
arrProcessesToKeep(11) = "audiodg.exe"
arrProcessesToKeep(12) = "mdm.exe"
arrProcessesToKeep(13) = "IAANTMon.exe" ' Intel RAID
arrProcessesToKeep(14) = "IAAnotif.exe" ' Intel RAID
arrProcessesToKeep(15) = "CTHELPER.EXE" ' Creative Labs Helper app.
arrProcessesToKeep(16) = "WmiPrvSE.exe"
arrProcessesToKeep(17) = "KHALMNPR.exe"
arrProcessesToKeep(18) = "SetPoint.exe" ' Logitech device
arrProcessesToKeep(19) = "cscript.exe" ' Don't kill the script itself.
arrProcessesToKeep(20) = "cmd.exe" ' Don't kill the script here either.
arrProcessesToKeep(21) = "taskmgr.exe" ' Leave task manager up.
'arrProcessesToKeep(22) = "vbsedt33.exe" ' debug
'<------------------------Functions and Procedures-------------------------->
' Function Exists in array?
Function fExists(oItem,sSearchString)
 fExists = False
 
 if IsArray(oItem) Then
   If InStr(LCase(Join(oItem,Chr(7))),Chr(7) & LCase(sSearchString) & Chr(7)) <> 0 Then fExists = True
 Else
   If InStr(LCase(oItem),LCase(sSearchString)) <> 0 Then fExists = True
 End If 
End Function
' Possible Service return codes (in English)
Function GetSvcErrorText(errorcode)
 Select Case errorcode
   case 0
     GetSvcErrorText = "Success"
   case 1
     GetSvcErrorText = "Not Supported"
   case 2
     GetSvcErrorText = "Access Denied"
   case 3
     GetSvcErrorText = "Dependent Services Running"
   case 4
     GetSvcErrorText = "Invalid Service Control"
   case 5
     GetSvcErrorText = "Service Cannot Accept Control"
   case 6
     GetSvcErrorText = "Service Not Active"
   case 7
     GetSvcErrorText = "Service Request timeout"
   case 8
     GetSvcErrorText = "Unknown Failure"
   case 9
     GetSvcErrorText = "Path Not Found"
   case 10
     GetSvcErrorText = "Service Already Stopped"
   case 11
     GetSvcErrorText = "Service Database Locked"
   case 12
     GetSvcErrorText = "Service Dependency Deleted"
   case 13
     GetSvcErrorText = "Service Dependency Failure"
   case 14
     GetSvcErrorText = "Service Disabled"
   case 15
     GetSvcErrorText = "Service Logon Failed"
   case 16
     GetSvcErrorText = "Service Marked For Deletion"
   case 17
     GetSvcErrorText = "Service No Thread"
   case 18
     GetSvcErrorText = "Status Circular Dependency"
   case 19
     GetSvcErrorText = "Status Duplicate Name"
   case 20
     GetSvcErrorText = "Status - Invalid Name"
   case 21
     GetSvcErrorText = "Status - Invalid Parameter"
   case 22
     GetSvcErrorText = "Status - Invalid Service Account"
   case 23
     GetSvcErrorText = "Status - Service Exists"
   case 24
     GetSvcErrorText = "Service Already Paused"
 End Select
End Function
' Possible Process return codes (in English)
Function GetProcErrorText(errorcode)
 Select Case errorcode
   case 0
     GetProcErrorText = "Successful Completion"
   case 2
     GetProcErrorText = "Access Denied"
   case 3
     GetProcErrorText = "Insufficient Privilege"
   case 8
     GetProcErrorText = "Unknown Failure"
   case 9
     GetProcErrorText = "Path Not Found"
   case 21
     GetProcErrorText = "Invalid Parameter"
 End Select
End Function
' Clears Console Window Buffer (fakes CLS)
Sub spoofCLS(byVal Lines)
 'If script is "silent" then exit
 If Wscript.Interactive <> 1 Then Exit Sub
 Dim ArExecBy,StrExecBy
 ArExecBy = Split(Wscript.FullName,"\")
 StrExecBy = Trim(UCase(ArExecBy(UBound(ArExecBy))))
 
 'stdout, stdin, and stderr methods supported
 'by cscript.exe only
 If StrExecBy = "CSCRIPT.EXE" AND CInt(Lines) > 0 Then
   'Clear Buffer
   Dim StdOut
   Set StdOut = WScript.StdOut
   StdOut.WriteBlankLines Lines
 Else
    wscript.echo "Run via cscript in an ELEVATED CMD.EXE: 'cscript vgl.vbs'!"
    wscript.quit(666)
 End If
End Sub
' Game Selection Input and Launch
Sub GamePicker()
 strProgName = ""
 strAppPath = ""
 Wscript.StdOut.Writeline
 Wscript.StdOut.Writeline "Launching Game Selection..."
 Wscript.StdOut.Writeline
 
 ' Show pick list, get game
 strProgName = inputbox("Choose a game -- hit OK..." & vbCR & vbCR & _
   "1. " & arrGames(0,0) & vbCR & "2. " & arrGames(1,0) & vbCR & "3. " & arrGames(2,0) & _
   vbCR & vbCR & "You can also type a full path here:", "VGL.vbs - Run what?", "")
  
 if (strProgName = "1") or (strProgName = "2") or (strProgName = "3") then 
   'Prest-o Change-o String-to-integer recast!  Yay scripts! :)
   strProgName = arrGames(strProgName-1, 1)
 end if
  
 ' Start Program and wait (true)
 If strProgName <> "" then
   Set objFileSystem = CreateObject("Scripting.FileSystemObject") 
   If objFileSystem.FileExists(strProgName) Then
    Set objShell = WScript.CreateObject("WScript.Shell")
    ' Get path portion
  arrPath = Split(strProgName, "\")
  For i = 0 to Ubound(arrPath) - 1
    StrAppPath = strAppPath & arrPath(i) & "\"
  Next 
  ' Switch to that folder
  objShell.CurrentDirectory = strAppPath
  Wscript.StdOut.Writeline "Current Path: " & objShell.CurrentDirectory
  Returncode = objShell.Run(chr(34) & strProgName & chr(34), 1, true) 
  Wscript.StdOut.Writeline "Returned. (Code: " & returncode & " - " & GetProcErrorText(returncode) & ")"
Else
  Wscript.StdOut.Writeline "File Not Found! (" & strProgName & ")"
End If
 Else
   Wscript.StdOut.Writeline "Cancelled by user (no path given)."
 End If

Set objShell = nothing
 Set objFileSystem = nothing
End Sub
' Exit option input
Sub DoneList()
 Set objShell = WScript.CreateObject("WScript.Shell")
 strExitOpt = 0
 
 While Not strExitOpt = 99
strExitOpt = inputbox("1. Reboot" & vbCR & "2. Shutdown" & _
  vbCR & "3. Start Explorer" & vbCR & "4. Start Task Manager" & vbCR & "5. Pick Another Game" & _
  vbCR & "Hit Enter to just exit script.","Exit Options:","")
if strExitOpt = "" Then
  strExitOpt = 99 ' Use to signify "exit" in Case/While statements.
Else
  ' Ensure it's a number
  If Not IsNumeric(strExitOpt) Then
    Wscript.StdOut.Writeline "Invalid Choice: " & strExitOpt
    strExitOpt = 101 ' Keeps the While loop going.
  End If
End If

Select Case strExitOpt
  case 1
 ' Reboot
 Wscript.StdOut.Writeline "Rebooting..."
 objShell.Run "shutdown.exe -r -f -t 00"
  case 2
 ' Shutdown
 Wscript.StdOut.Writeline "Shutdown..."
 objShell.Run "shutdown.exe -s -f -t 00"
  case 3
 ' Start Explorer
 Wscript.StdOut.Writeline "Launching Explorer.exe..."
 objShell.Run "explorer.exe"
  case 4
 ' Start Task Manager
 Wscript.StdOut.Writeline "Launching Task Manager..."
 objShell.Run "taskmgr.exe"
  case 5
 ' Pick a new game
 GamePicker
End Select
 Wend
 ' Quit Script
 Set objShell = nothing
 Wscript.StdOut.Writeline "Bye!"
 wscript.quit(0)
End Sub
'<--------------------------------Script Body------------------------------->
' Action Starts here.
' Clear the window, show the banner...
call spoofCLS(305)
Wscript.StdOut.Writeline "         _____              _      _        _____  _____  ______ _      "
Wscript.StdOut.Writeline "        |_   _|            | |    (_)      |  _  ||  _  ||___  /( )     "
Wscript.StdOut.Writeline "          | |    ___   ___ | |__   _   ___ | |/' || |/' |   / / |/  ___ "
Wscript.StdOut.Writeline "          | |   / _ \ / __|| '_ \ | | / _ \|  /| ||  /| |  / /     / __|"
Wscript.StdOut.Writeline "          | |  |  __/| (__ | | | || ||  __/\ |_/ /\ |_/ /./ /      \__ \"
Wscript.StdOut.Writeline "          \_/   \___| \___||_| |_||_| \___| \___/  \___/ \_/       |___/"
Wscript.StdOut.Writeline "           _   _  _       _            _____                         "
Wscript.StdOut.Writeline "          | | | |(_)     | |          |  __ \                        "
Wscript.StdOut.Writeline "          | | | | _  ___ | |_   __ _  | |  \/  __ _  _ __ ___    ___ "
Wscript.StdOut.Writeline "          | | | || |/ __|| __| / _` | | | __  / _` || '_ ` _ \  / _ \"
Wscript.StdOut.Writeline "          \ \_/ /| |\__ \| |_ | (_| | | |_\ \| (_| || | | | | ||  __/"
Wscript.StdOut.Writeline "           \___/ |_||___/ \__| \__,_|  \____/ \__,_||_| |_| |_| \___|"
Wscript.StdOut.Writeline "              _                                 _                 "
Wscript.StdOut.Writeline "             | |                               | |                "
Wscript.StdOut.Writeline "             | |      __ _  _   _  _ __    ___ | |__    ___  _ __ "
Wscript.StdOut.Writeline "             | |     / _` || | | || '_ \  / __|| '_ \  / _ \| '__|"
Wscript.StdOut.Writeline "v.42b        | |____| (_| || |_| || | | || (__ | | | ||  __/| |   "
Wscript.StdOut.Writeline "Dec'07       \_____/ \__,_| \__,_||_| |_| \___||_| |_| \___||_|   "
Wscript.StdOut.WriteBlankLines 4
Wscript.StdOut.Write "Press the ENTER to start the fun..."
WScript.StdIn.Readline
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colListOfRunningServices = objWMIService.ExecQuery _
 ("Select * from Win32_Service Where State='Running'") 
 
' Stop Dependants
if intloops < 1 then intLoops = 1  
For i = 1 to intLoops 
 Wscript.StdOut.Writeline
 Wscript.StdOut.Writeline "Stopping decendants (loop " & i & "/" & intLoops & ")..."
 Wscript.StdOut.Writeline
 
 for each objService2 in colListOfRunningServices
   Set colListOfServices = objWMIService.ExecQuery("Associators of " _
     & "{Win32_Service.Name='"& objService2.name & "'} Where " _
     & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
   For each objService in colListOfServices
     if not fExists(arrServicesToKeep, objService.displayname) then
       if (objService.state = "Running") Or (objService.state = "Paused") Or (objService.state = "Start Pending") _
   Or (objService.state = "Continue Pending") Or (objService.state = "Pause Pending") Then
         Wscript.StdOut.Writeline "Stopping " & objService.displayname & " (decendant of " & objService2.displayname & ")"
         returncode = objService.stopservice
         Wscript.StdOut.Writeline "Code: " & returncode & " - " & GetSvcErrorText(returncode)
         Wscript.StdOut.Writeline
       end if
     end if
   Next
 Next
 Wscript.StdOut.Writeline
 Wscript.StdOut.Writeline "Waiting 5 secs before next loop/continuation..."
 Wscript.StdOut.Writeline
 Wscript.Sleep 5000
Next
' Stop Parents
Wscript.StdOut.Writeline "Stopping Parents..."
Wscript.StdOut.Writeline
Set colListOfServices = objWMIService.ExecQuery _
("Select * from Win32_Service")
For Each objService in colListOfServices
 if not fExists(arrServicesToKeep,objService.displayname) then
   if (objService.state = "Running") Or (objService.state = "Paused") Or (objService.state = "Start Pending") _
     Or (objService.state = "Continue Pending") Or (objService.state = "Pause Pending") Then
     Wscript.StdOut.Writeline "Stopping " & objService.displayname
     returncode = objService.stopservice
     Wscript.StdOut.Writeline "Code: " & returncode & " - " & GetSvcErrorText(returncode)
     Wscript.StdOut.Writeline
   end if
 end if
Next 
Wscript.StdOut.Writeline "Done shutting down services."
Wscript.StdOut.Writeline
Wscript.StdOut.Writeline "Waiting 5 secs before continuing..."
Wscript.StdOut.Writeline
Wscript.Sleep 5000
Wscript.StdOut.Writeline "Shutting down processes..."
' Kill processes
For each objProcess in GetObject("winmgmts:{impersonationLevel=impersonate}!//localhost").ExecQuery _
 ("select * from Win32_Process")
 if not fExists(arrProcessesToKeep, objProcess.name) then
   Wscript.StdOut.Writeline "Stopping Process " & objProcess.Name & " (id " & objProcess.ProcessId & ")..."
   returncode = objProcess.Terminate(1)
   Wscript.StdOut.Writeline "Code: " & returncode & " - " & GetProcErrorText(returncode)
   Wscript.StdOut.Writeline
 end if
Next
Wscript.StdOut.Writeline
Wscript.StdOut.Writeline "Done shutting down processes."
' Clear our objects from memory
Set colListOfServices = nothing
Set colListOfRunningServices = nothing
Set objWMIService = nothing
' Start Input Loop
call GamePicker
call DoneList

Let me know how it works for ya. :)

It's 'official' home page is here: http://www.techiestools.com/vista_game_launcher_script.php
There's a little bit more info there on it's workings.

techie007

< Message edited by techie007 -- 12/26/2007 12:38:30 PM >

Revisions: 2 | Post #: 1

RE: Vista Cscript For Launching Games - 12/26/2007 10:54:34 AM

Meg

Posts: 125
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Hi Techie007, looks like a cool tool, there is code out there that forces the script to run under cscript even if you double click on the vbs that might be usefull to you.

I used a sub called forceUseCscript in my taskmonitor script that does this. You could give it a nice graphical front end using a HTA but mshta probably chews up more memory than cscript.
http://www.visualbasicscript.com/m_51868/mpage_1/key_forceUseCScript/tm.htm#54252

I don't use vista but maybe scripts like this will bring the vista operating system more on par with xp as far as gaming goes.

(in reply to techie007)

Post #: 2

RE: Vista Cscript For Launching Games - 12/26/2007 12:36:52 PM

techie007

Posts: 5
Score: 0
Joined: 12/11/2007
Status: offline

quote:

ORIGINAL: Meg

Hi Techie007, looks like a cool tool, there is code out there that forces the script to run under cscript even if you double click on the vbs that might be usefull to you.

I used a sub called forceUseCscript in my taskmonitor script that does this. You could give it a nice graphical front end using a HTA but mshta probably chews up more memory than cscript.

Actually it already has CScript detection code in it. But your point is well taken and I modified it to actually exit the entire script (errorlevel 666) when Cscript.exe isn't used. Thanks for the input! :)

quote:

ORIGINAL: Meg
I don't use vista but maybe scripts like this will bring the vista operating system more on par with xp as far as gaming goes.

So far I've had good luck with Vista and gaming, as good of luck as I ever had with XP anyway. Especially now that the video card drivers have (mostly) caught up -- so that's a good sign. :)

I'll update the original post with the latest version of the code, wish me luck... :)

techie007

(in reply to Meg)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Vista Cscript For Launching Games

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts