Perfmon Generator

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Perfmon Generator

Logged in as: Guest

arrSession:exec spGetSession 2,16,54690

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Perfmon Generator
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Perfmon Generator - 12/23/2007 3:04:03 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

I had the need to create about 10 counters for ~10 servers and didnt feel like adding them manually like I normally do. I also discovered that, after using perfmon for years, you can copy/paste an xml config file into perfmon to add counters so that is how this script came about.

'create perfmon xml file script
'this script will output an xml file that you can paste into
'perfmon to quickly add some standard counters to monitor
'for quite a few servers
'this script has been tested against vista & windows 2003 using
'both versions of mmc (2 & 3)

'header & footer
header = "<OBJECT ID='DISystemMonitor1' WIDTH='100%' HEIGHT='100%'" & vbnewline _
  & "CLASSID='CLSID:C4D2D8E0-D1DD-11CE-940F-008029004347'>" & vbnewline _
  & vbtab & "<PARAM NAME='_Version' VALUE='458755'/>" & vbnewline _
  & vbtab & "<PARAM NAME='_ExtentX' VALUE='32041'/>" & vbnewline _
  & vbtab & "<PARAM NAME='_ExtentY' VALUE='28443'/>" & vbnewline _
  & vbtab & "<PARAM NAME='DisplayType' VALUE='2'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ReportValueType' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='MaximumScale' VALUE='100'/>" & vbnewline _
  & vbtab & "<PARAM NAME='MinimumScale' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowLegend' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowToolbar' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowScaleLabels' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowHorizontalGrid' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowVerticalGrid' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ShowValueBar' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ManualUpdate' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='Highlight' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ReadOnly' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='MonitorDuplicateInstances' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='UpdateInterval' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='DisplayFilter' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='BackColorCtl' VALUE='15790320'/>" & vbnewline _
  & vbtab & "<PARAM NAME='ForeColor' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='BackColor' VALUE='12632256'/>" & vbnewline _
  & vbtab & "<PARAM NAME='GridColor' VALUE='8421504'/>" & vbnewline _
  & vbtab & "<PARAM NAME='TimeBarColor' VALUE='255'/>" & vbnewline _
  & vbtab & "<PARAM NAME='BorderStyle' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='TimeAxisLabels' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='Tooltip' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='NextColor' VALUE='4'/>" & vbnewline _
  & vbtab & "<PARAM NAME='NextCounterWidth' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='NextCounterLineStyle' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='MaximumSamples' VALUE='100'/>" & vbnewline _
  & vbtab & "<PARAM NAME='GraphTitle' VALUE=''/>" & vbnewline _
  & vbtab & "<PARAM NAME='YAxisLabel' VALUE=''/>" & vbnewline _
  & vbtab & "<PARAM NAME='DigitGrouping' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='WrapTimeLine' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='DataSourceType' VALUE='1'/>" & vbnewline _
  & vbtab & "<PARAM NAME='SqlDsnName' VALUE=''/>" & vbnewline _
  & vbtab & "<PARAM NAME='SqlLogSetName' VALUE=''/>" & vbnewline _
  & vbtab & "<PARAM NAME='LogFileCount' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='AmbientFont' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontName' VALUE='Segoe UI'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontSize' VALUE='9'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontItalic' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontUnderline' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontStrikethrough' VALUE='0'/>" & vbnewline _
  & vbtab & "<PARAM NAME='FontWeight' VALUE='400'/>" & vbnewline _
  & vbtab & "<PARAM NAME='LegendColumnWidths' VALUE='    0.080033698399326    0.080033698399326    0.20050547598989    0.100252737994945    0.100252737994945    0.20050547598989    0.160067396798652'/>" & vbnewline _
  & vbtab & "<PARAM NAME='LegendSortDirection' VALUE='-2'/>" & vbnewline _
  & vbtab & "<PARAM NAME='LegendSortColumn' VALUE='0'/>"
header1 = vbtab &"<PARAM NAME='MaximumSamples' VALUE='100'/>" & vbnewline _
  & vbtab & "<PARAM NAME='SampleCount' VALUE='100'/>" & vbnewline _
  & vbtab & "<PARAM NAME='SamplesSoFar' VALUE='1138'/>" & vbnewline _
  & vbtab & "<PARAM NAME='SampleIndex' VALUE='38'/>" & vbnewline _
  & vbtab & "<PARAM NAME='StepNumber' VALUE='37'/>" & vbnewline _
  & vbtab & "<PARAM NAME='TimeStamps' VALUE=''/>"
footer = vbtab & "<PARAM NAME='Selected: %s' VALUE=''/>" & vbnewline & "</OBJECT>"

'create objects
Set objSDictionary = CreateObject("Scripting.Dictionary")
Set objCDictionary = CreateObject("Scripting.Dictionary")
Set fso = CreateObject("Scripting.FileSystemObject")
outputfile = "counters.xml"
Set txtStreamOut = fso.OpenTextFile(outputfile, 2, True)

'color for the server,network card name to monitor
arr_server1 = array("256","Intel[R] PRO_100+ Management Adapter with Alert On LAN*")
arr_server2 = array("255","3Com 3C918 Integrated Fast Ethernet Controller [3C905B-TX Compatible]")
arr_server3 = array("65280","Intel[R] PRO_100 Network Connection")
arr_server4 = array("16711680","NETGEAR GA311 Gigabit Adapter")
arr_server5 = array("65535","Intel[R] PRO_1000 MB Dual Port Network Connection")
arr_server6 = array("10907866","Intel[R] PRO_1000 MB Dual Port Network Connection")
arr_server7 = array("16760576","Intel[R] PRO_1000 MB Dual Port Network Connection","\Web Service(_Total)\Current Anonymous Users","0")
arr_server8 = array("16711935","Intel[R] PRO_1000 MB Dual Port Network Connection","\Web Service(_Total)\Current Anonymous Users","0")
arr_server9 = array("11193702","Intel[R] PRO_1000 MB Dual Port Network Connection","\Web Service(_Total)\Current Anonymous Users","0")
arr_server10 = array("8388608","Intel[R] PRO_1000 MT Network Connection")

'hashtable with servernames and array of server specific stuff
objSDictionary.add "server1", arr_server1
objSDictionary.add "server2", arr_server2
objSDictionary.add "server3", arr_server3
objSDictionary.add "server4", arr_server4
objSDictionary.add "server5", arr_server5
objSDictionary.add "server6", arr_server6
objSDictionary.add "server7", arr_server7
objSDictionary.add "server8", arr_server8
objSDictionary.add "server9", arr_server9
objSDictionary.add "server10", arr_server10

'hash with perfmon counters and scale value
objCDictionary.add "\Memory\Available MBytes","-2"
objCDictionary.add "\PhysicalDisk(_Total)\% Disk Read Time","1"
objCDictionary.add "\PhysicalDisk(_Total)\% Disk Write Time", "1"
objCDictionary.add "\PhysicalDisk(_Total)\Avg. Disk Queue Length", "1"
objCDictionary.add "\PhysicalDisk(_Total)\Current Disk Queue Length", "1" 
objCDictionary.add "\Processor(_Total)\% Processor Time", "0"
  
dim counter : counter = 0
'output header
printOut doublequotefix(header)
'loop through servers
For Each server In objSDictionary
  'extract array of server specific stuff
  arr_test = objSDictionary(server)
  color = arr_test(0)
  nicname = arr_test(1)
  'if there are any extra counters to be added on a per server basis, loop through those now and add them to the hashtable
     if ubound(arr_test) > 1 then
         for i = 2 to ubound(arr_test) step 2
             'counter,scale
             objCdictionary.add arr_test(i), arr_test(i + 1)
         next
     end if
  
  'add custom network interface counters with their scale
  objCDictionary.add "\Network Interface(" & nicname & ")\Bytes Received/sec", "-4"
  objCDictionary.add "\Network Interface(" & nicname & ")\Bytes Sent/sec", "-4"
  
  'loop through perfmon counters per server
  for each pmobj in objCDictionary
      counter = counter + 1
      'add a leading zero if less than 10
      if counter < 10 then  counter = "0" & counter end if
      perserver = vbtab & "<PARAM NAME='Counter000" & counter & ".Path' VALUE='\\" & server & pmobj & "'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Color' VALUE='" & color & "'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Width' VALUE='1'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".LineStyle' VALUE='0'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".ScaleFactor' VALUE='" & objCDictionary(pmobj) & "'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Show' VALUE='1'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Selected' VALUE='1'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Minimum' VALUE='4352'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Maximum' VALUE='4358'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".Average' VALUE='4354.48'/>" & vbnewline _
      & vbtab & "<PARAM NAME='Counter000" & counter & ".StatisticStatus' VALUE='0'/>" & vbnewline
      wscript.echo perserver
      totalcounters = totalcounters & perserver
  next
  
  objCDictionary.remove "\Network Interface(" & nicname & ")\Bytes Received/sec"
  objCDictionary.remove "\Network Interface(" & nicname & ")\Bytes Sent/sec"
     if ubound(arr_test) > 1 then
           for i = 2 to ubound(arr_test) step 2
               'counter,scale
               objCdictionary.remove arr_test(i)
           next
       end if
next

'take off leading zero if less than 10
if counter < 10 then counter = right(counter,1) end if
'total counters count
total = vbtab & "<PARAM NAME='CounterCount' VALUE='" & counter & "'/>" & vbnewline
'output total counters
printOut doublequotefix(total)
'finish header
printOut doublequotefix(header1)
'output counters
printOut doublequotefix(totalcounters)
'output footer
printOut doublequotefix(footer)

function doublequotefix(data)
  'do a replace on single quotes with double quotes so I dont have to fix all the double quotes in the xml :)
  doublequotefix = replace(data,"'","""")
end function 'doublequotefix

Sub printOut(data)
  WScript.Echo data
  txtStreamOut.writeline data
End Sub 'printOut

< Message edited by kirrilian -- 12/26/2007 9:22:44 AM >

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site