File Checker MD5

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

File Checker MD5

Logged in as: Guest

arrSession:exec spGetSession 2,16,54787

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> File Checker MD5
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

File Checker MD5 - 12/30/2007 2:36:21 PM

Meg

Posts: 125
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Check the integrity of files saved to a backup - We All test our backups right?
Other uses are placing on removable media that you distribute to customers. - When run with a checksum file present it will kick into checking mode and report if any of YOUR files have been corrupted/deleted/modified etc.

I wrote this application in a day. Sorry only tested on XP Pro. Would appreciate any feedback if can find a use for it.

This is an HTML application, create a file on your computer called checker.hta and paste the following code into it.
Double click to run.

<html>
<head>
<title>CD Files Checker</title>

<HTA:APPLICATION 
     ID="objCDFilesChecker"
     APPLICATIONNAME="CDFilesChecker"
     SCROLL="no"
     WindowState="Maximise"
     SINGLEINSTANCE="yes"
     Version="0.01"
>
</head>

' ###################################################
' # Start MD5 Code written by http://www.frez.co.uk #
' ###################################################
 
' VBScript code for generating an MD5 'digest' or 'signature' of a string. The
' MD5 algorithm is one of the industry standard methods for generating digital
' signatures. It is generically known as a digest, digital signature, one-way
' encryption, hash or checksum algorithm. A common use for MD5 is for password
' encryption as it is one-way in nature, that does not mean that your passwords
' are not free from a dictionary attack.
'
' This is 'free' software with the following restrictions:
'
' You may not redistribute this code as a 'sample' or 'demo'. However, you are free
' to use the source code in your own code, but you may not claim that you created
' the sample code. It is expressly forbidden to sell or profit from this source code
' other than by the knowledge gained or the enhanced value added by your own code.
'
' Use of this software is also done so at your own risk. The code is supplied as
' is without warranty or guarantee of any kind.
'
' Should you wish to commission some derivative work based on this code provided
' here, or any consultancy work, please do not hesitate to contact us.
'
' Web Site:  http://www.frez.co.uk

Dim sDigest

Private Const BITS_TO_A_BYTE = 8
Private Const BYTES_TO_A_WORD = 4
Private Const BITS_TO_A_WORD = 32

Private m_lOnBits(30)
Private m_l2Power(30)
 
    m_lOnBits(0) = CLng(1)
    m_lOnBits(1) = CLng(3)
    m_lOnBits(2) = CLng(7)
    m_lOnBits(3) = CLng(15)
    m_lOnBits(4) = CLng(31)
    m_lOnBits(5) = CLng(63)
    m_lOnBits(6) = CLng(127)
    m_lOnBits(7) = CLng(255)
    m_lOnBits(8) = CLng(511)
    m_lOnBits(9) = CLng(1023)
    m_lOnBits(10) = CLng(2047)
    m_lOnBits(11) = CLng(4095)
    m_lOnBits(12) = CLng(8191)
    m_lOnBits(13) = CLng(16383)
    m_lOnBits(14) = CLng(32767)
    m_lOnBits(15) = CLng(65535)
    m_lOnBits(16) = CLng(131071)
    m_lOnBits(17) = CLng(262143)
    m_lOnBits(18) = CLng(524287)
    m_lOnBits(19) = CLng(1048575)
    m_lOnBits(20) = CLng(2097151)
    m_lOnBits(21) = CLng(4194303)
    m_lOnBits(22) = CLng(8388607)
    m_lOnBits(23) = CLng(16777215)
    m_lOnBits(24) = CLng(33554431)
    m_lOnBits(25) = CLng(67108863)
    m_lOnBits(26) = CLng(134217727)
    m_lOnBits(27) = CLng(268435455)
    m_lOnBits(28) = CLng(536870911)
    m_lOnBits(29) = CLng(1073741823)
    m_lOnBits(30) = CLng(2147483647)
    
    m_l2Power(0) = CLng(1)
    m_l2Power(1) = CLng(2)
    m_l2Power(2) = CLng(4)
    m_l2Power(3) = CLng(8)
    m_l2Power(4) = CLng(16)
    m_l2Power(5) = CLng(32)
    m_l2Power(6) = CLng(64)
    m_l2Power(7) = CLng(128)
    m_l2Power(8) = CLng(256)
    m_l2Power(9) = CLng(512)
    m_l2Power(10) = CLng(1024)
    m_l2Power(11) = CLng(2048)
    m_l2Power(12) = CLng(4096)
    m_l2Power(13) = CLng(8192)
    m_l2Power(14) = CLng(16384)
    m_l2Power(15) = CLng(32768)
    m_l2Power(16) = CLng(65536)
    m_l2Power(17) = CLng(131072)
    m_l2Power(18) = CLng(262144)
    m_l2Power(19) = CLng(524288)
    m_l2Power(20) = CLng(1048576)
    m_l2Power(21) = CLng(2097152)
    m_l2Power(22) = CLng(4194304)
    m_l2Power(23) = CLng(8388608)
    m_l2Power(24) = CLng(16777216)
    m_l2Power(25) = CLng(33554432)
    m_l2Power(26) = CLng(67108864)
    m_l2Power(27) = CLng(134217728)
    m_l2Power(28) = CLng(268435456)
    m_l2Power(29) = CLng(536870912)
    m_l2Power(30) = CLng(1073741824)

Private Function LShift(lValue, iShiftBits)
    If iShiftBits = 0 Then
        LShift = lValue
        Exit Function
    ElseIf iShiftBits = 31 Then
        If lValue And 1 Then
            LShift = &H80000000
        Else
            LShift = 0
        End If
        Exit Function
    ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
        Err.Raise 6
    End If

If (lValue And m_l2Power(31 - iShiftBits)) Then
        LShift = ((lValue And m_lOnBits(31 - (iShiftBits + 1))) * m_l2Power(iShiftBits)) Or &H80000000
    Else
        LShift = ((lValue And m_lOnBits(31 - iShiftBits)) * m_l2Power(iShiftBits))
    End If
End Function

Private Function RShift(lValue, iShiftBits)
    If iShiftBits = 0 Then
        RShift = lValue
        Exit Function
    ElseIf iShiftBits = 31 Then
        If lValue And &H80000000 Then
            RShift = 1
        Else
            RShift = 0
        End If
        Exit Function
    ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
        Err.Raise 6
    End If
    
    RShift = (lValue And &H7FFFFFFE) \ m_l2Power(iShiftBits)

If (lValue And &H80000000) Then
        RShift = (RShift Or (&H40000000 \ m_l2Power(iShiftBits - 1)))
    End If
End Function

Private Function RotateLeft(lValue, iShiftBits)
    RotateLeft = LShift(lValue, iShiftBits) Or RShift(lValue, (32 - iShiftBits))
End Function

Private Function AddUnsigned(lX, lY)
    Dim lX4
    Dim lY4
    Dim lX8
    Dim lY8
    Dim lResult
 
    lX8 = lX And &H80000000
    lY8 = lY And &H80000000
    lX4 = lX And &H40000000
    lY4 = lY And &H40000000
 
    lResult = (lX And &H3FFFFFFF) + (lY And &H3FFFFFFF)
 
    If lX4 And lY4 Then
        lResult = lResult Xor &H80000000 Xor lX8 Xor lY8
    ElseIf lX4 Or lY4 Then
        If lResult And &H40000000 Then
            lResult = lResult Xor &HC0000000 Xor lX8 Xor lY8
        Else
            lResult = lResult Xor &H40000000 Xor lX8 Xor lY8
        End If
    Else
        lResult = lResult Xor lX8 Xor lY8
    End If
 
    AddUnsigned = lResult
End Function

Private Function F(x, y, z)
    F = (x And y) Or ((Not x) And z)
End Function

Private Function G(x, y, z)
    G = (x And z) Or (y And (Not z))
End Function

Private Function H(x, y, z)
    H = (x Xor y Xor z)
End Function

Private Function I(x, y, z)
    I = (y Xor (x Or (Not z)))
End Function

Private Sub FF(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(F(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub

Private Sub GG(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(G(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub

Private Sub HH(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(H(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub

Private Sub II(a, b, c, d, x, s, ac)
    a = AddUnsigned(a, AddUnsigned(AddUnsigned(I(b, c, d), x), ac))
    a = RotateLeft(a, s)
    a = AddUnsigned(a, b)
End Sub

Private Function ConvertToWordArray(sMessage)
    Dim lMessageLength
    Dim lNumberOfWords
    Dim lWordArray()
    Dim lBytePosition
    Dim lByteCount
    Dim lWordCount
    
    Const MODULUS_BITS = 512
    Const CONGRUENT_BITS = 448
    
    lMessageLength = Len(sMessage)
    
    lNumberOfWords = (((lMessageLength + ((MODULUS_BITS - CONGRUENT_BITS) \ BITS_TO_A_BYTE)) \ (MODULUS_BITS \ BITS_TO_A_BYTE)) + 1) * (MODULUS_BITS \ BITS_TO_A_WORD)
    ReDim lWordArray(lNumberOfWords - 1)
    
    lBytePosition = 0
    lByteCount = 0
    Do Until lByteCount >= lMessageLength
        lWordCount = lByteCount \ BYTES_TO_A_WORD
        lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE
        lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(Asc(Mid(sMessage, lByteCount + 1, 1)), lBytePosition)
        lByteCount = lByteCount + 1
    Loop

lWordCount = lByteCount \ BYTES_TO_A_WORD
    lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE

lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(&H80, lBytePosition)

lWordArray(lNumberOfWords - 2) = LShift(lMessageLength, 3)
    lWordArray(lNumberOfWords - 1) = RShift(lMessageLength, 29)
    
    ConvertToWordArray = lWordArray
End Function

Private Function WordToHex(lValue)
    Dim lByte
    Dim lCount
    
    For lCount = 0 To 3
        lByte = RShift(lValue, lCount * BITS_TO_A_BYTE) And m_lOnBits(BITS_TO_A_BYTE - 1)
        WordToHex = WordToHex & Right("0" & Hex(lByte), 2)
    Next
End Function

Public Function MD5(sMessage)
    Dim x
    Dim k
    Dim AA
    Dim BB
    Dim CC
    Dim DD
    Dim a
    Dim b
    Dim c
    Dim d
    
    Const S11 = 7
    Const S12 = 12
    Const S13 = 17
    Const S14 = 22
    Const S21 = 5
    Const S22 = 9
    Const S23 = 14
    Const S24 = 20
    Const S31 = 4
    Const S32 = 11
    Const S33 = 16
    Const S34 = 23
    Const S41 = 6
    Const S42 = 10
    Const S43 = 15
    Const S44 = 21

x = ConvertToWordArray(sMessage)
    
    a = &H67452301
    b = &HEFCDAB89
    c = &H98BADCFE
    d = &H10325476

For k = 0 To UBound(x) Step 16
        AA = a
        BB = b
        CC = c
        DD = d
    
        FF a, b, c, d, x(k + 0), S11, &HD76AA478
        FF d, a, b, c, x(k + 1), S12, &HE8C7B756
        FF c, d, a, b, x(k + 2), S13, &H242070DB
        FF b, c, d, a, x(k + 3), S14, &HC1BDCEEE
        FF a, b, c, d, x(k + 4), S11, &HF57C0FAF
        FF d, a, b, c, x(k + 5), S12, &H4787C62A
        FF c, d, a, b, x(k + 6), S13, &HA8304613
        FF b, c, d, a, x(k + 7), S14, &HFD469501
        FF a, b, c, d, x(k + 8), S11, &H698098D8
        FF d, a, b, c, x(k + 9), S12, &H8B44F7AF
        FF c, d, a, b, x(k + 10), S13, &HFFFF5BB1
        FF b, c, d, a, x(k + 11), S14, &H895CD7BE
        FF a, b, c, d, x(k + 12), S11, &H6B901122
        FF d, a, b, c, x(k + 13), S12, &HFD987193
        FF c, d, a, b, x(k + 14), S13, &HA679438E
        FF b, c, d, a, x(k + 15), S14, &H49B40821
    
        GG a, b, c, d, x(k + 1), S21, &HF61E2562
        GG d, a, b, c, x(k + 6), S22, &HC040B340
        GG c, d, a, b, x(k + 11), S23, &H265E5A51
        GG b, c, d, a, x(k + 0), S24, &HE9B6C7AA
        GG a, b, c, d, x(k + 5), S21, &HD62F105D
        GG d, a, b, c, x(k + 10), S22, &H2441453
        GG c, d, a, b, x(k + 15), S23, &HD8A1E681
        GG b, c, d, a, x(k + 4), S24, &HE7D3FBC8
        GG a, b, c, d, x(k + 9), S21, &H21E1CDE6
        GG d, a, b, c, x(k + 14), S22, &HC33707D6
        GG c, d, a, b, x(k + 3), S23, &HF4D50D87
        GG b, c, d, a, x(k + 8), S24, &H455A14ED
        GG a, b, c, d, x(k + 13), S21, &HA9E3E905
        GG d, a, b, c, x(k + 2), S22, &HFCEFA3F8
        GG c, d, a, b, x(k + 7), S23, &H676F02D9
        GG b, c, d, a, x(k + 12), S24, &H8D2A4C8A
            
        HH a, b, c, d, x(k + 5), S31, &HFFFA3942
        HH d, a, b, c, x(k + 8), S32, &H8771F681
        HH c, d, a, b, x(k + 11), S33, &H6D9D6122
        HH b, c, d, a, x(k + 14), S34, &HFDE5380C
        HH a, b, c, d, x(k + 1), S31, &HA4BEEA44
        HH d, a, b, c, x(k + 4), S32, &H4BDECFA9
        HH c, d, a, b, x(k + 7), S33, &HF6BB4B60
        HH b, c, d, a, x(k + 10), S34, &HBEBFBC70
        HH a, b, c, d, x(k + 13), S31, &H289B7EC6
        HH d, a, b, c, x(k + 0), S32, &HEAA127FA
        HH c, d, a, b, x(k + 3), S33, &HD4EF3085
        HH b, c, d, a, x(k + 6), S34, &H4881D05
        HH a, b, c, d, x(k + 9), S31, &HD9D4D039
        HH d, a, b, c, x(k + 12), S32, &HE6DB99E5
        HH c, d, a, b, x(k + 15), S33, &H1FA27CF8
        HH b, c, d, a, x(k + 2), S34, &HC4AC5665
    
        II a, b, c, d, x(k + 0), S41, &HF4292244
        II d, a, b, c, x(k + 7), S42, &H432AFF97
        II c, d, a, b, x(k + 14), S43, &HAB9423A7
        II b, c, d, a, x(k + 5), S44, &HFC93A039
        II a, b, c, d, x(k + 12), S41, &H655B59C3
        II d, a, b, c, x(k + 3), S42, &H8F0CCC92
        II c, d, a, b, x(k + 10), S43, &HFFEFF47D
        II b, c, d, a, x(k + 1), S44, &H85845DD1
        II a, b, c, d, x(k + 8), S41, &H6FA87E4F
        II d, a, b, c, x(k + 15), S42, &HFE2CE6E0
        II c, d, a, b, x(k + 6), S43, &HA3014314
        II b, c, d, a, x(k + 13), S44, &H4E0811A1
        II a, b, c, d, x(k + 4), S41, &HF7537E82
        II d, a, b, c, x(k + 11), S42, &HBD3AF235
        II c, d, a, b, x(k + 2), S43, &H2AD7D2BB
        II b, c, d, a, x(k + 9), S44, &HEB86D391
    
        a = AddUnsigned(a, AA)
        b = AddUnsigned(b, BB)
        c = AddUnsigned(c, CC)
        d = AddUnsigned(d, DD)
    Next
    
    MD5 = LCase(WordToHex(a) & WordToHex(b) & WordToHex(c) & WordToHex(d))
End Function

' #################################################
' # End MD5 Code written by http://www.frez.co.uk #
' #################################################

' #################################################
' #     Start MD5 CD File Tester By MJP 2007      #
' #################################################

Dim CMDName, CMDPath, MyMD5
strComputer = "."                   
strLog = "cd.md5"

'--------------------------------------------------

Sub Window_Onload
    window.resizeto 800,600
    HTAScriptPath
'Check if checksum log file exists
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    If objFSO.FileExists(CMDPath&strLog) Then
       set objFile = nothing
       run_button1.disabled = true
       messages.value="Checking all files for errors or changes"
       sleep 1
       ReadLog
       messages.value=messages.value&vbcrlf&"Check Complete"
    Else
       About
       run_button2.disabled = true
    End if
End Sub

'--------------------------------------------------

Sub Create
    run_button1.disabled = true
    messages.value=""
    pos=len(CMDPath)
    strFolder = left(CMDPath, pos-1)
'Scan all files in current path
    ListFiles strFolder
    ListFolders strFolder
    WriteLog "End"
    run_button2.disabled = false
end sub

'--------------------------------------------------

sub Check
'Read checksum log file and process
    messages.value="Checking all files for errors or changes"
    readlog
    messages.value=messages.value&vbcrlf&"Check Complete"
end sub

'--------------------------------------------------

Sub Quit
    self.close 
end sub

'--------------------------------------------------

sub ListFiles(strFolder)
'List all files in the folder
	Set objWMIService = GetObject("winmgmts:" _
	    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
	
	Set colFileList = objWMIService.ExecQuery _
	    ("ASSOCIATORS OF {Win32_Directory.Name='"&strfolder&"'} Where " _
	        & "ResultClass = CIM_DataFile")
	
	For Each objFile In colFileList
'Build LogFile Entry - checksum + file path\name
            ReadMD5 objFile.Name
            CMDLen=len(CMDPath)
            pos=len(objFile.Name)
            strLine=right(objFile.Name, pos-CMDLen+1)
            strLine = MyMD5&vbtab&strLine
            WriteLog strLine
	Next
end sub

'--------------------------------------------------------------

sub ListFolders(strFolder)
'List all the subfolders in the folder
    on error resume next
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colSubfolders = objWMIService.ExecQuery _
        ("Associators of {Win32_Directory.Name='"&strfolder&"'} " _
            & "Where AssocClass = Win32_Subdirectory " _
                & "ResultRole = PartComponent")
    For Each objFolder in colSubfolders
        ListFiles objFolder.Name              'Sub- List all files in the folder
        ListFolders objFolder.Name            'Sub- List all the subfolders in the folder - Yes I am calling the same sub from within
    Next
end sub

'--------------------------------------------------------------

Sub WriteLog(strLine)
'Create log file and set header line if it is new
    Const ForAppending = 8
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    If objFSO.FileExists(CMDPath&strLog) Then
       '
    Else
       Set objFile = objFSO.CreateTextFile(CMDPath&strLog)
       strLine= "This is the CD Files Checker CheckSum File" 
    End If
    set objFile = nothing

'Open log file, write line and close log file
    Set objTextFile = objFSO.OpenTextFile (sCMDPath&strLog, ForAppending, True)
    objTextFile.WriteLine(strLine) 'append result to txt log file
    messages.value=messages.value&vbcrlf&strLine 
    objTextFile.Close 
End Sub

'--------------------------------------------------------------

Sub ReadLog
   on error resume next
   Const ForReading = 1
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set ts = fso.OpenTextFile(CMDPath&strLog, ForReading)
   Do 
       s = ts.ReadLine
       If s="This is the CD Files Checker CheckSum File" then
           'start scan
       else
	   If s="End" then 
	       exit Do
           Else
'Split checksum log file into two variables, hash and filename
               LogArray=split(s, vbtab, -1, 1)
               Flen=len(LogArray(1))
               LogArray(1)=right(LogArray(1),Flen-1)
               LogArray(1)=CMDPath&LogArray(1)
'Read MD5 of current file
               ReadMD5 LogArray(1)
               If MyMD5=LogArray(0) then
                  messages.value=messages.value&vbcrlf&"FILE OK - "&LogArray(1)
               Else
                  If err.number<>0 then 
                     messages.value=messages.value&vbcrlf&err.description&"- "&LogArray(1)
                  else
                     messages.value=messages.value&vbcrlf&"MD5 Fail- "&LogArray(1)
                  End If
               End if
           End if
       end if
       
   Loop 
   ts.Close
   On error goto 0
End Sub

'--------------------------------------------------------------

Sub ReadMD5(MyFileName)
'Read MD5 of current filename
    Const ForReading = 1
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.OpenTextFile(MyFileName, ForReading)
    s = ts.ReadAll
    MyMD5=MD5(s)   
    ts.Close
'added this so that display would update - 1ms sleep
    sleep 1
    window.resizeto 800,600
    messages.focus
end Sub

'--------------------------------------------------------------

Sub HTAScriptPath
'Determine Script Name and Path from HTA
    CMDLine=objCDFilesChecker.commandLine
    CMDLen=len(CMDLine)
    CMDLine=left(CMDLine, CMDLen-2)
    pos=InStrrev(CMDLine, "\")
    CMDName=right(CMDLine, CMDLen-pos-2)
    pos=InStr(CMDLine, CMDName)
    CMDPath=Left(CMDLine, pos-1)
    CMDPath=right(CMDPath, pos-2)
End Sub

'--------------------------------------------------------------

sub About
messages.value="CD Files Checker is an HTML application for checking the integrity of files."&vbcrlf&vbcrlf&_  
"In this digital day and age of information, everyone is madly creating. Traditionally, information has been stored on paper which has an archive life ~1year for a fax printed on thermal paper, ~20 years for a document on standard A4, ~100+ years for good books.  The quality of the medium and storage conditions drastically affect the longevity of your information and exactly the same can be said for digital data. Only with digital data, the medium is far more prone to degradation problems because you can not easily see if it is degrading and once you loose just a couple of those ones and zeros the whole file can be lost.  Quality stamped commercial CDs and DVDs have a 100 year plus life. Quality CDRs have up to 100 years if stored in a perfect environment. DVDRs, the jury is out on that one, I would not trust them past 5 years because I have not got a DVDR that is that old. Most of mine have deteriorated and died already, but hey I live in a humid part of the world. So that's where my CD Files Checker program comes in."&vbcrlf&vbcrlf&_
"Operation is very simple and self explanatory"&vbcrlf&vbcrlf&_
"File Checking Instructions"&vbcrlf&_
"1. Run checker.hta and watch it do it�s stuff"&vbcrlf&_
"2. If the program finds a checksum file it will scan that and report."&vbcrlf&vbcrlf&_ 
"Setup Checksum File"&vbcrlf&_
"1. Prepare a folder of files for archiving, can contain subfolders."&vbcrlf&_ 
"2. Place checker.hta in the root of that folder and run. "&vbcrlf&_
"3. Click �Create� button and program will create a checksum file. "&vbcrlf&_
"4. Archive folder along with checker.hta and checksum file. "&vbcrlf&_
"5. Can be burnt to the root of a CD or DVD"&vbcrlf&vbcrlf&vbcrlf&_
"# Copyright (C) 2008 Painterinfo"&vbcrlf&_
"# Script by MJP"&vbcrlf&_
"# "&vbcrlf&_
"# You have a royalty-free right to use, modify, reproduce and distribute"&vbcrlf&_
"# this script (and/or any modified version) in any way you find useful,"&vbcrlf&_
"# provided that you agree that Painterinfo or MJP has no"&vbcrlf&_
"# warranty, obligations or liability for the script. If you modify"&vbcrlf&_
"# the script, you must retain and abide by this and the MD5 copyright notice. "&vbcrlf&_
"# Thankyou"
end sub

'--------------------------------------------------------------

Sub Sleep(mSeconds) 
' sub to make the script pause for x mSeconds 
    strCmd = "%COMSPEC% /c ping -n 1 -w " & mSeconds & " 127.0.0.1>nul" 
    Set objShell=CreateObject("Wscript.shell") 
    objShell.Run strCmd,0,1 
End Sub

'--------------------------------------------------------------

</SCRIPT>
<body bgcolor=ffffff>

<input id=runbutton1  class="button" type="button" value="Create" name="run_button1"  onClick="Create">
<input id=runbutton2  class="button" type="button" value="Check" name="run_button2"  onClick="Check">
<input id=runbutton3  class="button" type="button" value="About" name="run_button3"  onClick="About">
<input id=runbutton4  class="button" type="button" value="Quit" name="run_button4"  onClick="Quit">
<font Size=4 face=tahoma color=red><b>CD Files Checker<b></font>
<br>
<textarea name="Messages" rows="28" cols="86"></textarea>

</td>
  </tr>
</table>

</body>
</html>

< Message edited by Meg -- 12/30/2007 8:24:50 PM >