[RESOLVED]Cannot find Error in Script

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

[RESOLVED]Cannot find Error in Script

Logged in as: Guest

arrSession:exec spGetSession 2,2,55013

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> [RESOLVED]Cannot find Error in Script
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1] 2 next > >>

Message

<< Older Topic Newer Topic >>

[RESOLVED]Cannot find Error in Script - 1/7/2008 12:26:39 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

This is actually a classic ASP page, but I thought you guys could help with this script..

I get an error of "Cannot Use Parenthese when calling a Sub" Error on Line 51, which is this:

response.Write "<br>Computer Found: " & rs(0)

This is what the script does...

There is a previous page with a drop down menu that is called "azou"

This script takes the value selected from the menu and checks the computer name that is stored in our login tracking database to see which computer that user is logged into.
Once it finds the computer, it is suppose to launch remote.exe on the client side with that computer name.

Here is the script

< Message edited by twilliamsen -- 1/11/2008 12:27:13 AM >

Post #: 1

RE: Cannot find Error in Script - 1/7/2008 12:29:17 AM

ebgreen

Posts: 4972
Score: 31
Joined: 7/12/2005
Status: offline

Which line is 51? Where ever it is, you will find that you are calling a Sub with () and you cannot do that in VBScript.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to twilliamsen)

Post #: 2

RE: Cannot find Error in Script - 1/7/2008 12:33:02 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

Line 51 is this:

response.Write "<br>Computer Found: " & rs(0)

If I change

oWshShell.run( path,0,false)

to

oWshShell.run path,0,false

The error goes away, but does not launch the EXE file.

(in reply to ebgreen)

Post #: 3

RE: Cannot find Error in Script - 1/7/2008 12:36:39 AM

ebgreen

Posts: 4972
Score: 31
Joined: 7/12/2005
Status: offline

Remove the On Error Resume Next and see what error you get.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to twilliamsen)

Post #: 4

RE: Cannot find Error in Script - 1/7/2008 12:41:32 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

Error...

Object required 'request'

Weird...

(in reply to ebgreen)

Post #: 5

RE: Cannot find Error in Script - 1/7/2008 12:46:42 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

not to harass you, but to help other readers/lurkers of this forum to
avoid the very common pitfall of calling Subs with () - would you consider
doing something about

http://www.visualbasicscript.com/fb.aspx?m=55012

After you solved your current problem, of course.

Regards

ehvbs

(in reply to ebgreen)

Post #: 6

RE: Cannot find Error in Script - 1/7/2008 12:50:01 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

the error message suggest to me, that your code is executed
clientside (no server side response object available). Where
should this code be executed?

(in reply to twilliamsen)

Post #: 7

RE: Cannot find Error in Script - 1/7/2008 12:53:19 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

I was not the post orignator.

Secondly, Yes, the EXE is called client side.

This could be either a permissions issue, or a Windows 2003 Server security issue.

Would this be better to wrap it into something else? A HTA or something?

(in reply to ehvbs)

Post #: 8

RE: Cannot find Error in Script - 1/7/2008 1:03:50 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

(a) for a quick test you could replace "response.write" with "document.write" (risk:
    destruction of page layout) or MsgBox (risk: many clicks).

(b) a (local) .HTA would avoid some permission/security trouble; in my opinion well
     worth a try

(c) "I was not the post orignator" - does that mean you don't feel responsible
     for the () in the .Run?

(in reply to twilliamsen)

Post #: 9

RE: Cannot find Error in Script - 1/7/2008 2:14:19 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

ehvbs..

a. nope, still errors, select box does not build

b. tried it... still errors

c. I have no idea where this all came from. I clarified an answer for the OP

(in reply to ehvbs)

Post #: 10

RE: Cannot find Error in Script - 1/7/2008 3:43:35 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

this .hta

<html>
<head>
 <hta:application id = "twilliamsen"
 />
 <title>twilliamsen</title>
 <meta http-equiv = "content-type" content="text/html; charset=iso-8859-1"/>
 <meta http-equiv = "content-script-type" content = "text/vbscript"/>
 <style type = "text/css">
  .stdBtt
  { width: 80;
  }
  .Meta
  { color: red;
  }
 </style>
 <script language = "VBScript"
         type     = "text/vbscript"
 >
'<![CDATA[

''= do something for twilliamsen
' ============================================================================
Sub doIt()
 ' Shell for CurrentDirectory and Run
 Dim oWSH : Set oWSH = CreateObject( "WScript.Shell" )

' get user name
 Dim sUser : sUser = Trim( document.getElementById( "sleUser" ).Value )
 If "" = sUser Then MsgBox "need user name" : Exit Sub

' get (last used) computer name from MSSQL
 Dim sSQL : sSQL    = Join( Array( _
              "SELECT top 1 sComputerName" _
            , "FROM   tblLogonLog.txt" _
            , "WHERE  sUserName = '" & sUser & "'" _
            , "ORDER  BY dtDateTime DESC" _
                                ), " " )
 Dim oCS  : oCS     = Join( Array( _
              "Provider=MSDASQL" _
            , "Driver={Microsoft Text Driver (*.txt; *.csv)}" _
            , "DBQ=" & oWSH.CurrentDirectory _
                                ), ";" )
 Dim oCN  : Set oCN = CreateObject( "ADODB.Connection" )
 oCN.Open oCS

Dim divFill : Set divFill = document.getElementById( "divFill" )
 Dim oRS     : Set oRS     = oCN.Execute( sSQL )
 If oRS.EOF Then
    sSQL    = Join( Array( _
              "SELECT distinct sComputerName" _
            , "FROM   tblLogonLog.txt" _
                         ), " " )
    Set oRS = oCN.Execute( sSQL )

Dim oNd
    Set oNd = document.createElement( "B" )
    oNd.appendChild document.createTextNode( "User '" & sUser & "' not found!" )
    divFill.appendChild oNd
    Set oNd = document.createElement( "BR" )
    divFill.appendChild oNd
    Set oNd = document.createElement( "SELECT" )

Dim aRows : aRows = oRS.GetRows()
    Dim nRow, oNd2
    For nRow = 0 To UBound( aRows, 2 )
'        MsgBox aRows( 0, nRow )
        Set oNd2 = document.createElement( "OPTION" )
        oNd2.appendChild document.createTextNode( aRows( 0, nRow ) )
        oNd.appendChild oNd2
    Next
    divFill.appendChild oNd

Else
    divFill.innerHTML = "<b>Computer '" & oRS( 0 ).Value & "' found!</b>"
 End If

' start .exe
 oWSH.Run "notepad.exe", 1, False

End Sub

''= refreshes the HTA page, which includes re-running any Windows_Onload code
' ============================================================================
Sub reloadHTA()
 location.reload True
End Sub

']]>
 </script>
</head>
<body>
 <hr />
 User name:
 <input id = "sleUser" type = "TEXT" value = "">
 <input id = "bttDoIt" class = "StdBtt" type = "BUTTON" value = "doIt" onclick = "doIt">
 <hr />
 <div id = "divFill">
 </div>
 <hr />
 <input class = "StdBtt Meta" type = "BUTTON" value = "reload" onclick = "reloadHTA">
</body>
</html>

demonstrates (very simple versions of) the things you want to do.

(a) Database query

(b) building a SELECT from a resultset

(c) starting an .exe

Because I don't have your tables in my MSDE DB, I had to use a .txt file as poor
man's database. For that you need a schema.ini

[tblLogonLog.txt]
Format=Delimited(|)
ColNameHeader=True
Col1=sComputerName TEXT
Col2=sUserName TEXT
Col3=dtDateTime DATE

and a fake table (=txt file)

sComputerName|sUserName|dtDateTime
Comp1|User1|1/1/2008 01:01:01
Comp2|User2|2/2/2008 02.02.02

in the directory of the .hta. Changing the connection string and the SQL field names
(possibe problems with names like DateTime (reserved word) had to be avoided)
should make the .hta suitable for your environment.

Good luck!

ehvbs

-------------------

(in reply to twilliamsen)

Post #: 11

RE: Cannot find Error in Script - 1/8/2008 12:48:12 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

ehvbs....

Interesting...

I will need to change quite a bit of the code since it is taking a value from a previous page. I will need to combine them.

But I see the concept. :)

I will play with it later!

Thanks!

(in reply to ehvbs)

Post #: 12

RE: Cannot find Error in Script - 1/11/2008 12:35:16 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

ehvbs...

I would like to thank you for pointing me to right direction. So far the HTA is working beautifully.

It is in its initial testing. I wish I can figure out a way to run the Remote Control button from Remote.exe instead of them manually doing so.

I tried SendKeys, but that just kept launching new instances of remote.exe untill I killed the HTA.

Here is the final code:

<html>
<head>
<hta:application id = "QAMonitoring"/>
<title>Quality Assurance Remote Monitoring</title>
<meta http-equiv = "content-type" content="text/html; charset=iso-8859-1"/>
<meta http-equiv = "content-script-type" content = "text/vbscript"/>
<style type = "text/css">
 .stdBtt
 { width: 100;
 }
 .Meta
 { color: red;
 }
</style>
<script language = "VBScript"
        type     = "text/vbscript"
>
'<![CDATA[

' ===================================================================
' Begin Active Directory User query, and build select box
' ===================================================================

Const ADS_SCOPE_SUBTREE = 2
Set objADO = CreateObject("ADODB.Connection")
Set objADOCommand = CreateObject("ADODB.Command")
objADO.Provider = "ADsDSOObject"
objADO.Open  "Active Directory Provider"
Set objADOCommand.ActiveConnection = objADO
objADOCommand.Properties("Page Size") = 10000
objADOCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
                      
                document.write ("<p align='center'><HR><font face='arial'> Please Select a Person to Monitor</font></hr></p>")
                document.write ("<BR>")
                document.write ("<BR>")
               objADOCommand.CommandText = "SELECT * FROM 'LDAP://OU=department,DC=corp,DC=corp,DC=com'"_
               & "WHERE objectCategory='person'"_
               & " AND objectClass='user' AND NOT (description='Mumbai')AND NOT (description='Fairfield') ORDER BY DisplayName "                                        
                                        
               ' Store Query results in a recordset
               Set objADUsers = objADOCommand.Execute
                               
               ' Check to make sure that the recordset has data
               if objADUsers.bof or objADUsers.eof then
                   document.createTextNode "No users returned."
               else
                   ' Set the pointer to the first record
                   objADUsers.MoveFirst
                   ' Create Drop Down Object
                   document.write ("<p align='center'><select name= 'sleUser'>")
                   ' iterate through recordset
                   Do Until objADUsers.EOF
                       ' Get Fields object
                       Set Fields = GetObject(objADUsers.Fields(0).value)
                       strSAM = Fields.Get("sAMAccountName")
                       strName = Fields.Get("DisplayName")  
                       ' Write out option
                       document.write ("<option value=" & strSAM & ">" & strName & "</option>" )
                      
                      
                       ' move to the next record in the set
                       objADUsers.MoveNext
                       
                    Loop
                    ' Close Drop Down object
                    document.write ("</select>")
                    document.write ("<BR>")
                    document.write ("<BR>")                     
               end if
'=========================================================================================================
' END ACTIVE DIRECTORY QUERY AND SELECT BUILD
' ========================================================================================================

'========================================================================================================
' START DOIT()
'
' Doit() grabs the local user's logon server name, matches the above select value with the LoginTracker Database
' Executes SMS's Remote.exe based on the location of the user using the application by using the logonServer variable
' =====================================================================================================================
Sub doIt()
On Error Resume Next
' Shell for CurrentDirectory and Run
Dim oWSH : Set oWSH = CreateObject( "WScript.Shell" )

set objNetwork = wscript.createObject("Wscript.Network")
 set wshProcess = owsh.Environment("Process")
 strLogonServer = wshProcess("LogonServer")
'msgbox(strLogonServer)
' get user name
Dim sUser : sUser = Trim( document.getElementById( "sleUser" ).Value )
If "" = sUser Then MsgBox "need user name" : Exit Sub
' get (last used) computer name from MSSQL
Dim sSQL : sSQL    = Join( Array( _
             "SELECT top 1 ComputerName " _
           , "FROM   tblLogonLog" _
           , "WHERE   Username = '" & sUser & "'" _
           , "ORDER  BY DateTime DESC" _
                               ), " " )
Dim oCS  : oCS     = Join( Array( _
             "Provider=MSDASQL" _
           , "Driver={SQL Server}; Server=10.0.0.26; Database=LoginTracker; UID=; PWD=" _
           , "DBQ=" & oWSH.CurrentDirectory _
                               ), ";" )
Dim oCN  : Set oCN = CreateObject( "ADODB.Connection" )
oCN.Open oCS
Dim divFill : Set divFill = document.getElementById( "divFill" )
Dim oRS     : Set oRS     = oCN.Execute( sSQL )
If oRS.EOF Then
   sSQL    = Join( Array( _
             "SELECT distinct UserName" _
           , "FROM   tblLogonLog" _
                        ), " " )
   Set oRS = oCN.Execute( sSQL )
   Dim oNd
   Set oNd = document.createElement( "B" )
   oNd.appendChild document.createTextNode( "User '" & sUser & "' not found!  Please select a user from the list below" )
   divFill.appendChild oNd
   Set oNd = document.createElement( "BR" )
   divFill.appendChild oNd
   
   Set oNd = document.createElement( "SELECT" )
   Dim aRows : aRows = oRS.GetRows()
   Dim nRow, oNd2
   For nRow = 0 To UBound( aRows, 2 )
'        MsgBox aRows( 0, nRow )
       Set oNd2 = document.createElement( "OPTION" )
       oNd2.appendChild document.createTextNode( aRows( 0, nRow ) )
       oNd.appendChild oNd2
   Next
   divFill.appendChild oNd
Else
   divFill.innerHTML = "<font face='arial'><p align='center'><b>Computer '" & oRS( 0 ).Value & "' found!</b></p></font>"
   
End If

' start .exe

'UNC path versions 
Select Case uCase(strLogonServer)
Case "\\Fileserver1"

' for Cherry Hill Users
oWSH.run "\\server2\remote$\remote.exe" & " 2 " & oRS( 0 ),1, false

Case "\\BACKUP"
' for Cherry Hill Users
oWSH.run "\\server2\remote$\remote.exe" & " 2 " & oRS( 0 ),1, false

Case "\\OH-DC01"

' for Ohio Users
oWSH.run "\\OH-DC01\remote$\remote.exe" & " 2 " & oRS( 0 ),1, false

End Select

End Sub

'======================================
' END DOIT()
'======================================
''= refreshes the HTA page, which includes re-running any Windows_Onload code
' ============================================================================
Sub reloadHTA()
location.reload True
End Sub
']]>
</script>
</head>
<body

(in reply to twilliamsen)

Post #: 13

RE: Cannot find Error in Script - 1/11/2008 12:47:06 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

as I don't know/use Remote.exe, I have no clue about how to help you. Can you
explain the problem a bit further? Does the Remote.exe application start? How
did you specify the target for your SendKeys? Perhaps someone more familiar
with SendKeys can spot the problem.

Good luck!

ehvbs

(in reply to twilliamsen)

Post #: 14

RE: Cannot find Error in Script - 1/11/2008 1:26:39 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

remote.exe is the application for Remote Tools for SMS. It has buttons/menus in it for different tools.

The tool that needs to be used is Remote Control.

I did try the following code, and this sent it into a loop of re-opening remote.exe till you killed the app

wscript.Sleep 12000
oWSH.SendKeys "{F10}"
wscript.sleep 5000
owsh.sendkeys "{ALT}"
wscript.sleep 1000
oWSH.SendKeys "T"
wscript.sleep 1000
oWSH.SendKeys "{ENTER} <--- if I comment this out then it doesn't loop

For some unknown reason the remote.exe window does not become the top most application launched.
I don't know if remote.exe is calling an EXE or a DLL or something, I don't know enough about it and I have not found any documentation on it either.

(in reply to ehvbs)

Post #: 15

RE: Cannot find Error in Script - 1/11/2008 1:40:05 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

I'm reduced to Voodoo here - but did you try to use .AppActivate to focus
the correct window?

(in reply to twilliamsen)

Post #: 16

RE: Cannot find Error in Script - 1/11/2008 1:54:18 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

No, I have not, and have no idea on how to use it or where to put it...

Without you going to write the code for me, let me look it up first :)

(in reply to ehvbs)

Post #: 17

RE: Cannot find Error in Script - 1/11/2008 1:57:00 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

that's the spirit!

(in reply to twilliamsen)

Post #: 18

RE: Cannot find Error in Script - 1/11/2008 2:02:35 AM

twilliamsen

Posts: 195
Score: 0
Joined: 1/18/2007
Status: offline

Ok, I got the appactive to work...

Is there a way to call a class in an application?

The class for the remote.exe I need is called smsRemoteControl in this HTA or is becoming outside the boundries of the HTA and VBS?

(in reply to ehvbs)

Post #: 19

RE: Cannot find Error in Script - 1/11/2008 2:13:18 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi twilliamsen,

I don't understand "call a class in an application"; I can't find
"smsRemoteControl" in the .hta code posted.

(not complaining or chiding you; just need help to try
to help you)

(in reply to twilliamsen)

Post #: 20

Page: [1] 2 next > >>

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> [RESOLVED]Cannot find Error in Script

Page: [1] 2<