Rename Photo's

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Rename Photo's

Logged in as: Guest

arrSession:exec spGetSession 2,16,55723

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Rename Photo's
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Rename Photo's - 1/19/2008 3:43:44 PM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

A while ago I created a script that would rename a file (photo) based on the date last modified, I posted it here so if you would like to see that one, search for Move and Rename pictures and you should find it.

One of the issues with this is if I connect my camera directly to my PC the datelastmodified can get screwed up. Had it happen once and it was a PITA to fix it.

Not too long ago, someone posted a script or a link to a script that read exif data and I started the basics then. Well, tonight I got a bug up my.... and decided to work on the script. I started with NameSpace and with the help of DM to get past a strange issue (thanks again DM_4ever), I was able to get a working script. The only issue I saw was when dealing with AVI files. My camera, and from what I read it seems to be standard, creates the avi file but then creates a THM file. This file is essentially a jpg and if you rename it to JPG you get exif data. But maybe I was just tired or whatever but with the way the original script was written I was having difficulty getting this working. So, I started searching for some EXIF command line tools and found jhead.exe. I started playing with this and one of the features that it has is if you give it a THM file it will rename it to JPG, get the exif data and rename the AVI file based on that info.

This is what I have so far:
My folder structure is
D:\NewPictures\Tools
D:\NewPictures\Backup (used while the script is in dev)
The script and jhead.exe are both in the tools folder

'Todo
' Convert current rename to rename using exif

' NOTE: Exif does not contain Seconds.  CHECK for file before creating.  Add suffix if needed.
' Build in support for files that do not have exif info
' Keep THM file for video's as this will contain exif info
' Rename THM to JPG to get EXIF date taken info?
'    Date Modified on THM MAY be different than date modified on movie file
'
Option Explicit

Dim strFolder
Dim IgnoredExtensions
Dim ie
Dim ret 
Dim scriptFolder 
Dim f, f1, fc, myArray,fileExtension,newFolder,strNewFile
Dim picCount : picCount = 0
Dim aviCount : aviCount = 0
Dim folderCount : folderCount = 0
Dim skipCount : skipCount = 0

Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
Dim wshShell : Set WshShell = WScript.CreateObject("WScript.Shell")

scriptFolder = fso.GetParentFolderName(WScript.ScriptFullName)

'Check if ignoredExtensions file is present.  This will be used to list extensions that do not need to be processed
If fso.FileExists(scriptFolder & "\IgnoredExtensions.txt") Then
   Set ie = fso.OpenTextFile(scriptFolder & "\IgnoredExtensions.txt", 1)
   IgnoredExtensions = ie.ReadAll
   ie.Close
Else
   IgnoredExtensions = ""
End If

'Path is Parent of Tools folder i.e. 
' ScriptFolder = d:\NewPictures\Tools
' strFolder default = d:\newPictures
strFolder = InputBox("enter in path to folder","Source",fso.GetParentFolderName(scriptFolder))
If strFolder = "" Then 
   WScript.Echo "Cancel"
   WScript.Quit
End If

'Set current folder to inputbox as this is where the files will be processed.  needed for jhead to function correctly as files need to be in same folder as exe
WshShell.CurrentDirectory = strFolder

'While in testing, create backup of all files.
ret = MsgBox("This script is still in test.  Do you want to create a backup?",vbYesNo)
If ret = vbYes Then
   Call doBackup 
End If

'Rename all JPG's to MM_DD_YYY_HHMMSS format (_ can be changed as needed)
WshShell.Run "cmd /c " & scriptFolder & "\jhead -nf%m_%d_%Y_%H%M%S *.jpg -v >" & scriptFolder & "\jpg.txt",0,True

'Rename all AVI's and THM's to MM_DD_YYY_HHMMSS format.  All THM's will be renamed to JPG
WshShell.Run "cmd /c " & scriptFolder & "\jhead -a -nf%m_%d_%Y_%H%M%S *.THM -v >" & scriptFolder & "\avi.txt",0,True

Set f = fso.GetFolder(strFolder)
Set fc = f.Files

For Each f1 in fc
    strNewFile = fnDate(f1.name)'set filename to be Month_DD_YYYY_HHMMSS format
    fileExtension = fso.GetExtensionName(lcase(strNewFile))
    If fileExtension = "jpg" Or fileExtension = "bmp" then
       picCount = picCount + 1'increment picCount(only for show)
       Call CopyFiles(f1.Path,strNewFile)
   ElseIf fileExtension = "avi" Then 
       aviCount = aviCount + 1'increment aviCount(only for show)
       Call CopyFiles(f1.Path,strNewFile)
   ElseIf lcase(strNewFile) = "thumbs.db" Then 'Delete thumbs.db if present
       f1.attributes = f1.attributes - 6
       fso.DeleteFile(f1.path)
   Else
       If InStr(IgnoredExtensions,fileExtension) = 0 Then
           ret = Msgbox(f1.Name & " is an unknown extension.  Do you want to add it to the Ignored Extensions file?",vbYesNo)
           If ret = vbYes Then
               Call UpdateIgnoredExtensions(fileExtension)
           End If 
       End If 
   End If 
Next

MsgBox picCount & " pictures have been processed" & vbcr _
& aviCount & " movies have been processed" & vbCr _ 
& folderCount & " folders have been created" & vbCr _ 
& skipCount & " files have been skipped"

Sub DoBackup()
   Dim backupCount : backupCount = 0
   Set f = fso.GetFolder(strFolder)
   Set fc = f.Files
   
   For Each f1 in fc
        strNewFile = f1.name
        fileExtension = fso.GetExtensionName(lcase(strNewFile))
        If Not (fileExtension = "jpg" Or fileExtension = "bmp" Or fileExtension = "avi") Then 
               'DoNothing
       End If 
   backupCount = backupCount + 1    
   fso.CopyFile f1.Path,strFolder & "\backup\" & f1.Name 
   Next
   MsgBox backupCount & " files have been backuped"
End Sub

Sub CopyFiles(originalFile,theFile)
   Dim cf
   myArray = Split(theFile,"_")
   'Set newfolder to equal first 3 parts of the File which will be
   ' Month(spelled out) DD and YYYY
   'ex January_01_2008
   newFolder = strFolder & "\" & myArray(0) & "_" & myArray(1) & "_" & myArray(2)

If Not fso.FolderExists(newFolder) Then 
       folderCount = folderCount + 1'increment folderCount(only for show)
       Set cf = fso.CreateFolder(newFolder) ' Create the folder as needed
   End If
   If Not fso.FileExists(newFolder & "\" & theFile) Then 
       'Move file to new folder renaming it in the process
       fso.MoveFile originalFile,newFolder & "\" & theFile
   Else
       skipCount = skipCount + 1'increment skipCount(only for show)
   End If 
End Sub

Function FnDate(Dt)
'Replace MM with Month
' i.e. 01 becomes January
   Dim tFnDate,Rnm
   tFnDate = Left(dt,2)

Select Case tFnDate
       Case "01" Rnm = "January"
       Case "02" Rnm = "February"
       Case "03" Rnm = "March"
       Case "04" Rnm = "April"
       Case "05" Rnm = "May"
       Case "06" Rnm = "June"
       Case "07" Rnm = "July"
       Case "08" Rnm = "August"
       Case "09" Rnm = "September"
       Case "10" Rnm = "October"
       Case "11" Rnm = "November"
       Case "12" Rnm = "December"
   End Select
   
   FnDate =  Rnm & "_" & Mid(dt,4,len(dt))
End Function

Sub UpdateIgnoredExtensions(theExtension)
'Update IgnoredExtensions
   Dim s
   Set s = fso.OpenTextFile(scriptFolder & "\IgnoredExtensions.txt", 8,True)'ForAppending
   s.WriteLine(theExtension)
   s.Close
End Sub

Thoughts? suggestions?

Well off to watch TV with the wife. Night all.

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.