RE: I need help, please help,

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

RE: I need help, please help,

Logged in as: Guest

arrSession:exec spGetSession 2,2,56229

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: I need help, please help,
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: << < prev 1 2 [3]

Message

<< Older Topic Newer Topic >>

RE: I need help, please help, - 2/5/2008 9:28:29 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

Here is a Backup to USB stick, I created/modified. Maybe you can take somthing from it.

'Create needed variables
Dim objNetwork, objFSO, RegExObj, variablesObj
Dim SOURCE, TARGET, FLDR_EXcLUDE, FILE_EXCLUDE
Dim replicate, synchronize, silent, hiddenFiles, hiddenFldrs
Dim sourceObj, subSourceObj, sourceFileObj, sourceFile, newSource
Dim targetObj, subTargetObj, targetFileObj, targetFile, newTarget
Dim WshShell, sUserName, X

Set WshShell = WScript.CreateObject("WScript.Shell")
Set objNetwork = wscript.CreateObject("wscript.network") 'objNetwork.Username
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set variablesObj = WScript.Arguments

Dim fso, dicUSBList, strComputer, objWMI, colDiskDrives, objDiskDrive, dicUSBDrives
Dim strDeviceID, strEscapedDeviceID, colDiskPartitions, objDiskPartition, strUSBDrive
Dim colLogicalDisks, objLogicalDisk
Dim sourceStick
Dim targetStick
Set fso = CreateObject("Scripting.FileSystemObject")

'Find USB Stick
Set dicUSBDrives = GetUSBDrives
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------
If dicUSBDrives.Count = 0 Then
WScript.Echo "No USB sticks found!"
Else
WScript.Echo "Found a USB stick:"
For Each strUSBDrive In dicUSBDrives
WScript.Echo "Using" & space(1) & strUSBDrive & "\" & space(1) & "for Backup"
Target = strUSBDrive & "\MyDocuments"
Next
End If

'---------------------------------------------------------------------------------------------------------------------------------------------------------------------

Function GetUSBDrives
' Populate a dictionary object with USB drive letters
Set dicUSBList = CreateObject("Scripting.Dictionary")
   dicUSBList.CompareMode = vbTextCompare
   strComputer = "."    ' use "." for local computer
   Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
   Set colDiskDrives = objWMI.ExecQuery ("Select DeviceID from Win32_DiskDrive WHERE InterfaceType='USB'")
           For Each objDiskDrive In colDiskDrives
                   strDeviceID = objDiskDrive.DeviceID
                   strEscapedDeviceID = Replace(strDeviceID, "\", "\\")
               Set colDiskPartitions = objWMI.ExecQuery _
                   ("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" &  strEscapedDeviceID & """} WHERE " _
                   &  "AssocClass = Win32_DiskDriveToDiskPartition")
           For Each objDiskPartition In colDiskPartitions
               Set colLogicalDisks = objWMI.ExecQuery ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & _
                   objDiskPartition.DeviceID & """} WHERE " & _
                   "AssocClass = Win32_LogicalDiskToPartition")
           For Each objLogicalDisk In colLogicalDisks
               dicUSBList.Add objLogicalDisk.DeviceID, ""
           Next
       Next
Next
Set GetUSBDrives = dicUSBList
End Function
'Notes On Input and Msg Boxes
'The InputBox function only has OK and Cancel buttons (unlike the MsgBox function that can have Yes, No, Cancel and OK).  The InputBox function only ever returns a string containing what was entered in the text box.  If Cancel is clicked it returns an empty string (e.g "").  You simply cannot test for VbCancel or VbOK with the InputBox function.

'The MsgBox function will return a value depending on the button clicked and each button has a value (e.g. VbNo, VbOK, VbYes, VbCancel)
'=======================================================
'=============== USER DEFINED VARIABLES ================
'=======================================================
sUserName = wshShell.ExpandEnvironmentStrings("%USERPROFILE%") 
SOURCE = sUserName & "\My Documents"
'================================================================================

'================================================================================

'******************************************************************************
'Asks to start the backup
X=MsgBox("Would you like to run Backup Now? ",36,"Last Chance")
If X = 6 Then 'If MsgBox is answered YES
Else
WScript.Quit 'If MsgBox is answered NO
End If
'Then if the targetpath (drive) on line 160 is not found quit
'******************************************************************************
'Excluded folders
'- list folder names, comma separated
FLDR_EXcLUDE = ""

'Excluded file types
'- list file extensions (without periods), comma separated
FILE_EXCLUDE = ""        'exe,txt
'****************************************************************************************************
'Replication
'1. Starts with source folder and if it doesn't exist on the target copies it and all contents there
'2. If the source folder does exist on the target it checks the files in that folder and copies any missing files or files with later modified dates to the target
'3. Recurses through all subfolders (all levels) in the source, repeating steps 1 & 2 for each

'Synchronization
'4. Starts with target folder and if it does not exist in the source deletes it.
'5. If the target folder does exist in source it goes through all files in the target folder and deletes them if they do not exist in the source
'6. Recurses through all sub folders (all levels) in the target, repeating steps 4 & 5 for each.
'****************************************************************************************************

replicate   = true     'Perform replication: true/false
synchronize = false    'Perform synchonization: true/false
silent      = false    'Show dialogs: true false
hiddenFldrs = true     'Process hidden folders: true/false
hiddenFiles = true     'Process hidden files: true/false
'       NOTE: If a folder is missing in the target, the entire
'             folder is copied, even the hidden files
'=======================================================

'Use variables passed from command line if sent
If WScript.Arguments.Count > 0 Then
 replicate = variablesObj(0)
End If
If WScript.Arguments.Count > 1 Then
 synchronize = variablesObj(1)
End If
If WScript.Arguments.Count > 2 Then
 silent = variablesObj(2)
End If

'Set up regular expression object
Set RegExObj = New RegExp
RegExObj.IgnoreCase = True
FILE_EXCLUDE = "," & FILE_EXCLUDE & ","
FLDR_EXCLUDE = "," & FLDR_EXCLUDE & ","

'Verify if source folder exists
If Not (objFSO.FolderExists(SOURCE)) Then
 'Do not replicate, Perform error handling
 If Not ( silent ) Then
   MsgBox "Source Missing"
 End If
'Proceed if replicating is on
ElseIf ( replicate ) Then
   replicateFolders SOURCE, TARGET
End If

'Verify if target folder exists
If Not (objFSO.FolderExists(TARGET)) Then
 'Do not synchronize, Perform error handling
 If Not ( silent ) Then
   MsgBox "Target Missing"
 End If
'Proceed if synching is on
ElseIf ( synchronize ) Then
   syncFolders SOURCE, TARGET
End If

'Cleanup variables
Set objFSO        = nothing
Set objNetwork    = nothing
Set variablesObj  = nothing
Set RegExObj      = nothing
Set sourceObj     = nothing
Set targetObj     = nothing
Set targetFileObj = nothing
Set sourceFileObj = nothing

If Not ( silent ) Then
 MsgBox "Backup Complete!", 0, "Done"
End If

'=======================================================
Sub replicateFolders (currentSource, currentTarget)
'=======================================================
'This procedure will call the procedure replicateFiles
'to process the files in the current directory. Then it
'will check the subfolders in the current directory. If
'a sub directory does not exist in the target it will be
'copied there. If it does exist the procedure will
'perform replicateSource on that directory as well
'=======================================================

'Check if target folder exists
 If Not (objFSO.FolderExists(currentTarget)) Then

'Create the target folder and copy the contents of currentSource there
   objFSO.CreateFolder(currentTarget)
   objFSO.CopyFolder currentSource, currentTarget

Else

'Create folder object of the currentSource
   Set sourceObj = objFSO.GetFolder(currentSource)

'Perform file replication for the currentSource
   replicateFiles sourceObj, currentTarget

'Do recursive processing of sub folders
   For Each subSourceObj in sourceObj.SubFolders
     If Not excluded(subSourceObj.Name,0,FLDR_EXCLUDE) Then
     If (hiddenFldrs) Or (Not subSourceObj.Attributes And 2) Then
       newTarget = TARGET & RIGHT(subSourceObj.Path,(Len(subSourceObj.Path)-Len(SOURCE)))
       replicateFolders subSourceObj.path, newTarget
     End If
     End If
   Next

End If

'=======================================================
End Sub 'replicateFolders
'=======================================================
'=======================================================
Sub replicateFiles (sourceObj, targetPath)
'=======================================================
 ' Recurse through all files in the source object
 For Each sourceFileObj in sourceObj.Files

If Not excluded(sourceFileObj.Name,1,FILE_EXCLUDE) Then
   If (hiddenFiles) Or (Not sourceFileObj.Attributes And 2) Then
    targetFile = targetPath & "\" & sourceFileObj.Name

'Check if file exists in target
     If objFSO.FileExists(targetFile) Then

'Create file object of target file
       Set targetFileObj = objFSO.GetFile(targetFile)

'Check if file in source is newer
       If sourceFileObj.DateLastModified > targetFileObj.DateLastModified Then
         'Overwrite existing file in target with newer source file
         sourceFileObj.Copy targetFile, true
       End If
     Else
       'Copy file from source to target
       sourceFileObj.Copy targetFile
     End If
   End If
   End If
 Next

'=======================================================
End Sub 'replicateFiles
'=======================================================
'=======================================================
Sub syncFolders (currentSource, currentTarget)
'=======================================================

'Check if source folder exists
 If Not (objFSO.FolderExists(currentSource)) Then

'Delete the current target folder
   objFSO.DeleteFolder currentTarget
 Else

'Create folder object of the currentTarget
   Set targetObj = objFSO.GetFolder(currentTarget)
   'Perform file synching for the currentTarget
   syncFiles currentSource, targetObj

'Do recursive processing of sub folders
   For Each subTargetObj in targetObj.SubFolders
     If Not excluded(subTargetObj.Name,0,FLDR_EXCLUDE) Then
     If (hiddenFldrs) Or (Not subTargetObj.Attributes And 2) Then
       newSource = SOURCE & RIGHT(subTargetObj.Path,(Len(subTargetObj.Path)-Len(TARGET)))
       syncFolders newSource, subTargetObj.path
     End If
     End If
   Next
 End If
'=======================================================
End Sub 'syncFolders
'=======================================================
'=======================================================
Sub syncFiles (sourcePath, targetObj)
'=======================================================
'=======================================================-
 ' Recurse through all files in the target object
 For Each targetFileObj in targetObj.Files

'Do not process excluded file types
   If Not excluded(targetFileObj.Name,1,FILE_EXCLUDE) Then
     sourceFile = sourcePath & "\" & targetFileObj.Name

'Delete target file if does not exist in source
     If Not (objFSO.FileExists(sourceFile)) Then
       targetFileObj.Delete true
     End If
   End If
 Next
'=======================================================
End Sub 'syncFiles
'=======================================================
Function excluded (itemName,isFile,excludeList)
'=======================================================
' Test if itemName is in excluded list
'=======================================================-
 'If file, get the file extension
 If isFile Then
   itemName = Right(itemName,Len(itemName)-InStrRev(itemName,"."))
 End If

RegExObj.Pattern = "," & itemName & ","
 excluded = RegExObj.Test(excludeList)
'=======================================================
End Function 'excluded
'=======================================================

_____________________________

"You start coding. I'll go find out what they want."

(in reply to dmp_92)

Post #: 41

RE: I need help, please help, - 2/6/2008 1:35:41 AM

dmp_92

Posts: 70
Score: 0
Joined: 2/1/2008
Status: offline

One last question for you guys. The code I have that copies over the files is base if the files are less then an hour old. What if I just want to copy the files on what is more current?

This is the code I have

For Each file in objFolderA.Files
   If dateDiff("d", file.DateCreated, Date) < 2 Then 'copy file if it's "2 days old"
        'MsgBox "objFSO.CopyFile " & file.Path & ", " & UsbKey
        objFSO.CopyFile file.Path, UsbKey
   End If

(in reply to gdewrance)

Post #: 42

RE: I need help, please help, - 2/6/2008 1:45:48 AM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

something like this

For Each file in objFolderA.Files
If DateDiff("n", file.DateLastModified, Now) =< 60 Then
objFSO.CopyFile file.Path, UsbKey
End If

_____________________________

"You start coding. I'll go find out what they want."

(in reply to dmp_92)

Post #: 43

RE: I need help, please help, - 2/6/2008 2:46:40 AM

dmp_92

Posts: 70
Score: 0
Joined: 2/1/2008
Status: offline

That's great.

Thanks,

(in reply to gdewrance)

Post #: 44

RE: I need help, please help, - 2/15/2008 3:09:04 AM

dmp_92

Posts: 70
Score: 0
Joined: 2/1/2008
Status: offline

I need to make a slight change to the script. I will post the first section.

Option Explicit
'Dim objWMIService, objItem, colItems
Dim strComputer, strMbox, ArrDriveType, WMI, coldisks, disk, strtype, strID, strSys, UsbKey, file, USBFound
Dim objFSO:Set objFSO=CreateObject("Scripting.FileSystemObject")
Dim objFolderA: Set objFolderA=objFSO.GetFolder("\\bluewater\departments$\Information Technology\test\")

'****************** check to see if the files are more current ************************************************

' For Each file in objFolderA.Files
' Check for reg key "here"
' if no reg key found on computer then continue with script
' if reg key is more current then file then
' WScript.Quit

'**************************************************************************************************************

The last part of the script that needs to be modified is this

'*********************************** Change this section to just copy all current files and place a reg key somewhere on the PC ***********

For Each file in objFolderA.Files
   If DateDiff("n", file.DateLastModified, Now) =< 60 Then
          objFSO.CopyFile file.Path, UsbKey
   End If

' after files are copied over create msg box to say that all files have been copied over succesfully ********************
'************************************************************************************************************************

(in reply to dmp_92)

Post #: 45

RE: I need help, please help, - 2/15/2008 3:11:39 AM

dmp_92

Posts: 70
Score: 0
Joined: 2/1/2008
Status: offline

The reg key that gets placed on the computer should be a date stamp. If this possible I do not even know.

(in reply to dmp_92)

Post #: 46

Page: << < prev 1 2 [3]

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: I need help, please help,

Page: << < prev 1 2 [3]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts