Comparision of two time stamps

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Comparision of two time stamps

Logged in as: Guest

arrSession:exec spGetSession 2,2,58902

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Comparision of two time stamps
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Comparision of two time stamps - 4/8/2008 1:29:13 AM

shahid09

Posts: 58
Score: 0
Joined: 1/22/2007
Status: offline

Hi All,

I want to compare two timestamp and want to get the one which is most latest one. my time stamp format is

TimeStamp1 = 07/03/2008 10:34:55:93746
TimeStamp2 = 07/01/2008 13:35:05:15023

I want to compare these timestamps and get the one which is the most current. In thiis case Timestamp1 is the answer. I tried to create write code but it is not working.

Problem in this code is If newDate is greater but time is lessor I don't get desired output.

Thanks
MK

Post #: 1

RE: Comparision of two time stamps - 4/8/2008 1:38:58 AM

ebgreen

Posts: 4972
Score: 31
Joined: 7/12/2005
Status: offline

Wow. The code you posted wouldn't even run. Please post the code that you are actually running.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to shahid09)

Post #: 2

RE: Comparision of two time stamps - 4/8/2008 1:53:36 AM

ehvbs

Posts: 2173
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi shahid09,

you may try this:

Dim dicLocale : Set dicLocale = CreateObject( "Scripting.Dictionary" )
 dicLocale.Add "Current", GetLocale()
 dicLocale.Add "French" , 1036
 dicLocale.Add "en-gb"  , 2057
 dicLocale.Add "en-us"  , "en-us" ' 1033

SetLocale dicLocale( "en-us" )

Dim aTests

aTests = Array( _
     "15.12.2005 14:50:03:95712", "07.02.2007 12:44:27:25506", -1 _
   , "07.02.2007 12:44:27:25506", "15.12.2005 14:50:03:95712",  1 _
   , "07.02.2007 12:44:27:25506", "07.02.2007 12:44:27:25506",  0 _
   , "15.12.2005 14:50:03:95712", "15.12.2005 14:50:03:95712",  0 _
   , "15.12.2005 14:50:03:00001", "15.12.2005 14:50:03:00000",  1 _
   , "15.12.2005 14:50:03:00000", "15.12.2005 14:50:03:00001", -1 _
               )

aTests = Array( _
     "12/15/2005 14:50:03:95712", "02/07/2007 12:44:27:25506", -1 _
   , "02/07/2007 12:44:27:25506", "12/15/2005 14:50:03:95712",  1 _
   , "02/07/2007 12:44:27:25506", "02/07/2007 12:44:27:25506",  0 _
   , "02/07/2007 12:44:27:25506", "02/07/2007 12:44:27:25507", -1 _
   , "02/07/2007 12:44:28:25506", "02/07/2007 12:44:27:25506",  1 _
   , "02/07/2007 12:44:28:25506", "02/07/2007 12:44:29:25506", -1 _
   , "12/16/2005 14:50:03:95712", "12/17/2005 14:50:03:95712", -1 _
   , "02/08/2007 12:44:27:25506", "02/07/2007 12:44:27:25506",  1 _
   , "08/02/2007 12:44:27:25506", "09/01/2007 12:44:27:25506", -1 _
   , "08/10/2008 12:44:27:25506", "10/08/2008 12:44:27:25506", -1 _
               )

Dim nIdx, nRes
 For nIdx = 0 To UBound( aTests ) Step 3
     nRes = TStampComp( aTests( nIdx + 0 ), aTests( nIdx + 1 ) )
     WScript.Echo   aTests( nIdx + 0 ), aTests( nIdx + 1 ), "C", Right( " " & nRes, 2 ) _
                  , "E", CStr( nRes = aTests( nIdx + 2 ) )
 Next
 SetLocale dicLocale( "Current" )
 WScript.Quit 0

Function TStampComp( stsLHS, stsRHS )
 If stsLHS = stsRHS Then
    TStampComp = 0
 Else
    Dim aLHS : aLHS = convTS2DT( stsLHS )
    Dim aRHS : aRHS = convTS2DT( stsRHS )
    If     aLHS( 0 ) < aRHS( 0 ) Then
       TStampComp = -1
    ElseIf aLHS( 0 ) > aRHS( 0 ) Then
       TStampComp =  1
    Else
       If     aLHS( 1 ) < aRHS( 1 ) Then
          TStampComp = -1
       ElseIf aLHS( 1 ) > aRHS( 1 ) Then
          TStampComp =  1
       Else
          TStampComp = 0
       End If
    End If
 End If
End Function

Function convTS2DT( sTStamp )
 Dim oRE    : Set oRE  = New RegExp
 oRE.Pattern = "^(\d{1,2}/\d{1,2}/\d{4} \d{2}:\d{2}:\d{2}):(\d+)$"    ' en
 oRE.Pattern = "^(\d{1,2}\.\d{1,2}\.\d{4} \d{2}:\d{2}:\d{2}):(\d+)$"  ' de
 oRE.Pattern = "^(\d{1,2}.\d{1,2}.\d{4} \d{2}:\d{2}:\d{2}):(\d+)$"    ' both
 Dim oMTS   : Set oMTS = oRE.Execute( sTStamp )
 If 1 = oMTS.Count Then
    Dim dtRVal : dtRVal = CDate( oMTS( 0 ).Submatches( 0 ) )
    Dim lRVal  : lRVal  = CLng(  oMTS( 0 ).Submatches( 1 ) )
    convTS2DT = Array( dtRVal, lRVal )
 Else
    Err.Raise 4711, "bad sTStamp " & sTStamp, "convTS2DT()"
 End If
End Function

output:

but you'll have to test it carefully, because possible locale problems may make my tests
useless.

Good luck!

ehvbs

(in reply to shahid09)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Comparision of two time stamps

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts