Object Not a Collection

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Object Not a Collection

Logged in as: Guest

arrSession:exec spGetSession 2,2,60333

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Object Not a Collection
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Object Not a Collection - 5/17/2008 2:36:40 PM

TNO

Posts: 1284
Score: 12
Joined: 12/18/2004
From: thenewobjective.com
Status: online

While trying to plug this into the framework, I keep coming across this error when testing on an empty array and a couple other things, what am I not seeing?

Function JoinX(arr,sep)
	ReDim aClone(UBound(arr))
	Dim nIdx : nIdx = 0
	Dim vElm
	For Each vElm In Array1
		aClone(nIdx) = CStrX(vElm)
		nIdx = nIdx + 1
	Next
	JoinX = Join(aClone,sep)
End Function

Function CStrX(Item)
	Dim sRVal
	Select Case VarType(Item)
		Case vbEmpty	'0 Uninitialized (default)
			sRVal = "<vbEmpty>"
		Case vbNull	'1 Contains no valid data
			sRVal = "<vbNull>"
		Case vbInteger	'2 Integer subtype
			sRVal = CStr(Item)
		Case vbLong	'3 Long subtype
			sRVal = CStr(Item)
		Case vbSingle	'4 Single subtype
			sRVal = CStr(Item)
			sRVal = Replace(sRVal,",",".")
		Case vbDouble	'5 Double subtype
			sRVal = CStr(Item)
			sRVal = Replace(sRVal, ",", "." )
		Case vbCurrency	'6 Currency subtype
			sRVal = CStr(Item)
			sRVal = Replace(sRVal, ",", "." )
		Case vbDate	'7 Date subtype
			sRVal = CStr(Item)
		Case vbString	'8 String subtype
			sRVal = """" + Item + """"
		Case vbObject	'9 Object
			If Item Is Nothing Then
				sRVal = "<Nothing>"
			Else
				sRVal = TypeName(Item)
				Select Case sRVal
					Case "Dictionary"
						Dim vKey
						sRVal = ""
						For Each vKey In Item.Keys
							sRVal = sRVal + "," + CStrX(vKey) + "=>" + CStrX(Item(vKey))
						Next
						sRVal = "{" + Mid(sRVal,2) + "}"
					Case Else
						sRVal = "{" & sRVal & " Object}"
					End Select
			End If
		Case vbError	'10 Error subtype
		Case vbBoolean	'11 Boolean subtype
			sRVal = CStr(Item)
		Case vbVariant	'12 Variant (used only for arrays of variants)
		Case vbDataObject	'13 Data access object
		Case vbDecimal	'14 Decimal subtype
		Case vbByte	'17 Byte subtype
		Case vbArray	'8192 Array
		Case 8204	'Array of Variants
			sRVal = "[" + JoinX(Item,",") + "]"
		Case Else
			sRVal = "<Unknown>"
	End Select
	CStrX = sRVal
End Function

Dim arrTest : arrTest = Array()

MsgBox CStrX(arrTest)

< Message edited by TNO -- 5/17/2008 2:37:46 PM >

_____________________________

To iterate is human, to recurse divine. -- L. Peter Deutsch

Post #: 1

RE: Object Not a Collection - 5/17/2008 5:25:08 PM

dm_4ever

Posts: 2665
Score: 46
Joined: 6/29/2006
From: Orange County, California
Status: offline

I could be wrong but Array1 is not defined anywhere

Function JoinX(arr,sep)
ReDim aClone(UBound(arr))
Dim nIdx : nIdx = 0
Dim vElm
For Each vElm In Array1
aClone(nIdx) = CStrX(vElm)
nIdx = nIdx + 1
Next
JoinX = Join(aClone,sep)
End Function

Should Array1 be arr?

< Message edited by dm_4ever -- 5/17/2008 5:26:13 PM >

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to TNO)

Post #: 2

RE: Object Not a Collection - 5/17/2008 10:54:01 PM

TNO

Posts: 1284
Score: 12
Joined: 12/18/2004
From: thenewobjective.com
Status: online

You sir are a gentleman, a scholar and a saint. I shall dance at your wedding.

_____________________________

To iterate is human, to recurse divine. -- L. Peter Deutsch

(in reply to dm_4ever)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Object Not a Collection

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts