Passing Variables from a VBScript to an HTA

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Passing Variables from a VBScript to an HTA

Logged in as: Guest

arrSession:exec spGetSession 2,2,62886

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Passing Variables from a VBScript to an HTA
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Passing Variables from a VBScript to an HTA - 7/29/2008 2:05:54 AM

chiltz

Posts: 76
Score: 0
Joined: 6/13/2007
Status: offline

Hey All you Guru's,

I built a vb script for the purpose of passing variables to an HTA. The intent is that multiple HTA's will be open depending on the number of lines in an xls spreadhseet. The spreadsheet contains the data that will go into the variables. VBS opens the spreadsheet, lets you enter data, then passes that data to HTA via commandline variables.

Now for the problem. Inorder for the commandline to work properly, I have to wrap the variables in double quotes. When I do this, I get "unexpected end of statement errors". If I wrap the variables in single quotes, then the path is invalid cuz it has spaces. Anybody know how I can use double quotes in the below for loop? Specifically in the Shell.Run command.

Complete script is below for refrence:

Option Explicit
Dim intRow , excelfilename, htafile , rowCount
Dim ArgCH, ArgNH, ArgCIP, ArgNIP, ArgSM, ArgGW
Dim objFSO, objExcel, objSheet , objShell
excelfilename = "c:\setuphta.xls"
htafile = "C:\Documents and Settings\myuseridhere\Desktop\Scripts - Work in Progress\Rename and ReIP\objtesthta.hta"
'********************************************************************************
'********************************************************************************
'********************************************************************************
'**************************RUNNING THE SCRIPT************************************
'********************************************************************************
'********************************************************************************
'********************************************************************************
Set objExcel = CreateObject("Excel.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")
If Not objFSO.FileExists(excelfilename) Then
 objExcel.Workbooks.Add
 objExcel.ActiveWorkbook.SaveAs excelfilename
Else
 objExcel.Workbooks.open(excelFileName)
End If
Set objSheet = objExcel.ActiveWorkbook.Worksheets(1)
objExcel.Visible = True
objSheet.Cells(1, 1).Value = "Current Host"
objSheet.Cells(1, 2).Value = "New Host"
objSheet.Cells(1, 3).Value = "Current IP"
objSheet.Cells(1, 4).Value = "New IP"
objSheet.Cells(1, 5).Value = "New Subnet"
objSheet.Cells(1, 6).Value = "New Gateway"
objExcel.Range("A1:F1").Select
objExcel.Selection.Font.Bold = True
objExcel.Selection.Interior.ColorIndex = 6
objExcel.Selection.Columns.AutoFit
MsgBox "Fill In Info Required for all lines required and Click OK Once Finished"
objExcel.ActiveSheet.UsedRange.Select
rowCount = objExcel.Selection.Rows.Count
For intRow = 2 to rowCount 
 ArgCH = objSheet.Cells(intRow, 1).Value
 ArgNH = objSheet.Cells(intRow, 2).Value
 ArgCIP = objSheet.Cells(intRow, 3).Value
 ArgNIP = objSheet.Cells(intRow, 4).Value
 ArgSM = objSheet.Cells(intRow, 5).Value
 ArgGW = objSheet.Cells(intRow, 6).Value
 Set objShell = CreateObject("WScript.Shell")
 'MsgBox "%comspec% /k '" & htafile & "' '" & ArgCH & "' '" & ArgNH & "' '" & ArgCIP & "' '" & ArgNIP & "' '" & ArgSM & "' '" & ArgGW & "'"
 objShell.Run("%comspec% /k '" & htafile & " '" & ArgCH & "' '" & ArgNH & "' '" & ArgCIP & "' '" & ArgNIP & "' '" & ArgSM & "' '" & ArgGW & "'")
Next

< Message edited by chiltz -- 7/29/2008 2:07:53 AM >

Post #: 1

RE: Passing Variables from a VBScript to an HTA - 7/29/2008 2:21:46 AM

dm_4ever

Posts: 2669
Score: 46
Joined: 6/29/2006
From: Orange County, California
Status: offline

Man this looks messy but try

"%comspec% /k """ & htafile & """ """ & ArgCH & """ """ & ArgNH & """ """ & ArgCIP & """ """ & ArgNIP & """ """ & ArgSM & """ """ & ArgGW & """"

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to chiltz)

Post #: 2

RE: Passing Variables from a VBScript to an HTA - 7/29/2008 4:44:24 AM

chiltz

Posts: 76
Score: 0
Joined: 6/13/2007
Status: offline

Below is a working version of the script. The key is to use the variable version of double quotes "chr(34)" instead of the actual double quotes. For those wondering how to make use of those varabiles in the HTA, make a "Windows_Onload" sub and direct the variables as you see fit...for me, I am writing them from the array into another variable inside the HTA.

Option Explicit
Dim intRow , excelfilename, htafile , rowCount
Dim ArgCH, ArgNH, ArgCIP, ArgNIP, ArgSM, ArgGW
Dim objFSO, objExcel, objSheet , objShell
excelfilename = "c:\setuphta.xls"
htafile = "C:\RenameReIP\objtesthta.hta"
'********************************************************************************
'********************************************************************************
'********************************************************************************
'**************************RUNNING THE SCRIPT************************************
'********************************************************************************
'********************************************************************************
'********************************************************************************
Set objExcel = CreateObject("Excel.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")
If Not objFSO.FileExists(excelfilename) Then
  objExcel.Workbooks.Add
  objExcel.ActiveWorkbook.SaveAs excelfilename
Else
  objExcel.Workbooks.open(excelFileName)
End If
Set objSheet = objExcel.ActiveWorkbook.Worksheets(1)
objExcel.Visible = True
objSheet.Cells(1, 1).Value = "Current Host"
objSheet.Cells(1, 2).Value = "New Host"
objSheet.Cells(1, 3).Value = "Current IP"
objSheet.Cells(1, 4).Value = "New IP"
objSheet.Cells(1, 5).Value = "New Subnet"
objSheet.Cells(1, 6).Value = "New Gateway"
objExcel.Range("A1:F1").Select
objExcel.Selection.Font.Bold = True
objExcel.Selection.Interior.ColorIndex = 6
objExcel.Selection.Columns.AutoFit
MsgBox "Fill In Info Required for all lines required and Click OK Once Finished"
objExcel.ActiveSheet.UsedRange.Select
rowCount = objExcel.Selection.Rows.Count
For intRow = 2 to rowCount 
  ArgCH = objSheet.Cells(intRow, 1).Value
  ArgNH = objSheet.Cells(intRow, 2).Value
  ArgCIP = objSheet.Cells(intRow, 3).Value
  ArgNIP = objSheet.Cells(intRow, 4).Value
  ArgSM = objSheet.Cells(intRow, 5).Value
  ArgGW = objSheet.Cells(intRow, 6).Value
  Set objShell = CreateObject("WScript.Shell")
  objShell.Run("%comspec% /k " & htafile & _
                 " " & chr(34) & ArgCH & chr(34) & _
                 " " & chr(34) & ArgNH & chr(34) & _
                 " " & chr(34) & ArgCIP & chr(34) & _
                 " " & chr(34) & ArgNIP & chr(34) & _
                 " " & chr(34) & ArgSM & chr(34) & _
                 " " & chr(34) & ArgGW & chr(34))
Next

(in reply to chiltz)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Passing Variables from a VBScript to an HTA

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts