Own3d Jukebox

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Own3d Jukebox

Logged in as: Guest

arrSession:exec spGetSession 2,16,63074

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Own3d Jukebox
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Own3d Jukebox - 8/3/2008 10:38:43 PM

TomRiddle

Posts: 191
Score: 4
Joined: 2/7/2008
Status: offline

Nice and simple little HTA for playing your mp3 music out of your speakers or out of any other computer's speakers that you own on the network.
Code is reasonably commented and more is displayed about the program when you run it for the first time and when you click the close button.

Correct me if I am wrong but no one else has written a media player before that uses a remote computer's speakers.

Copy and paste the below code into a file with HTA extension. Enjoy

<HTML> 
<head> 
<title>0wn3d Jukebox</title>

<hta:application 
     applicationname="JukeBox"    
     ID="objJukeBox" 
     SCROLL="yes" 
     SINGLEINSTANCE="yes" 
     SHOWINTASKBAR="yes" 
     CAPTION="yes" 
     CONTEXTMENU="no" 
     Version="1.5"

Option Explicit

Dim strComputer, strLocalFolder, strINI, iTimerID, CurrentSong 
   Dim dictFiles : Set dictFiles = CreateObject("Scripting.Dictionary") 
   Dim dictNoFiles : Set dictNoFiles = CreateObject("Scripting.Dictionary") 
   Dim dictPlayedFiles : Set dictPlayedFiles = CreateObject("Scripting.Dictionary")

'------------------------------------------------------------------------------

Sub AboutOJ

'Press the close button to read this

Dim About : About = _ 
   "Concept and Script by TomRiddle 2008"&vbcrlf&_ 
   vbcrlf&_ 
   "I like to listen to mp3s but not through my own computer speakers pointed straight at my face. "&vbcrlf&_ 
   "Build a play list, Pick a computer on your network to be your speakers and magically control via 0wn3d Jukebox. "&vbcrlf&_ 
   vbcrlf&_ 
   "Own3d Jukebox is designed and tested on networks of Windows XP Pro computers. Only MP3 files are supported sorry. "&vbcrlf&_ 
   "No firewalls, local admin access required, i.e. you need to own the target computer in order to use its speakers. "&vbcrlf&_ 
   vbcrlf&_ 
   "Word of warning, YES you own the computer playing the music, but you are the one Own3d if your boss fires you for mischief. "&vbcrlf&_ 
   "This program is for computers you own. Any dumb user can work out who has Own3d their speakers by looking at Task Manager.  So enjoy but don't get into trouble. "&vbcrlf&_ 
   vbcrlf&_ 
   "P.s. This script was written with many snippets from www.visualbasicscript.com. Cred goes to the posters on that forum. "&vbcrlf&_ 
   "Post bugs and other comments on this script�s thread."

msgbox About

end sub

'------------------------------------------------------------------------------ 
  
Sub Window_Onload

'Run at HTA initialisation

Self.ResizeTo 600, Screen.Height-45 
   Self.MoveTo (Screen.Width/2)-300,5

PlayButton.disabled = true

'get Temp folder and build ini file name 
   Dim objShell : Set objShell = CreateObject("WScript.Shell") 
   Dim strTempDir : strTempDir = objShell.ExpandEnvironmentStrings("%temp%") 
   strINI=strTempDir&"\LastOwned.ini" 
    
   INIRead

strOwnedComputer.innerhtml = strComputer 
   root_path.innerhtml = strLocalFolder 
      
   If strLocalFolder <> "" Then 
       displayPageFull GetFiles(strLocalFolder), dictNoFiles, dictPlayedFiles, CurrentSong 
   End If

end sub

'------------------------------------------------------------------------------

Sub INIRead

'read ini file to give the script a memory of last machine Own3d 
  
   Dim objFSO, objFile, objNet 
   Const ForReading =  1    
  
   Set objFSO=CreateObject("Scripting.FileSystemObject") 
   if objFSO.FileExists(strINI) then 
      Set objFile = objFSO.OpenTextFile(strINI, ForReading) 
      strcomputer = objFile.ReadLine 
      strLocalFolder = objFile.ReadLine 
      
      if reachable(strComputer) then 
         exit sub 
      else 
         Dim Warning : Warning = MsgBox (strComputer& " is offline, do you want to revert to this computer's speakers?", 276, "Own3d Jukebox Warning") 
         if Warning = 6 then 
            Set objNet = CreateObject("WScript.NetWork") 
            strcomputer = objNet.ComputerName 
         End if 
      end if 
   else 
     'When ini file does not exist use this computer's speakers as default 
      Set objNet = CreateObject("WScript.NetWork") 
      strcomputer = objNet.ComputerName 
      strLocalFolder = "" 
      INISet strComputer, strLocalFolder 
      AboutOJ 
   end if

End sub

'------------------------------------------------------------------------------

Sub INISet(strComputer, strLocalFolder)

'write to ini file to give the script a memory of last machine Own3d

Dim objFSO, objFile

Set objFSO = CreateObject("Scripting.FileSystemObject")  
   Set objFile = objFSO.CreateTextFile(strINI) 
   objFile.WriteLine(strComputer) 
   objFile.WriteLine(strLocalFolder) 
   objFile.Close

End Sub

'------------------------------------------------------------------------------

Sub MainGetFiles()

'Set Source folder path

strLocalFolder = BrowseForFolder 
   root_path.innerhtml = strLocalFolder 
      
   If strLocalFolder <> "" Then 
       displayPageFull GetFiles(strLocalFolder), dictNoFiles, dictPlayedFiles, CurrentSong 
   End If

End Sub

'------------------------------------------------------------------------------ 
  
Function GetFiles(strPath)

'Read all files in source folder

on error resume next

Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject") 
      
   If objFSO.FolderExists(strPath) Then 
      Dim objFolder : Set objFolder = objFSO.GetFolder(strPath) 
      Dim objFile 
      For Each objFile In objFolder.Files

'filter audio files only 
         if AudioExt(objFile.Name) then 
            dictFiles.Add objFile.Path, objFile.Name 
         end if

Next 
   End If 
      
   Set GetFiles = dictFiles

if err<> 0 then msgbox "Failed to read source files"

on error goto 0 
    
End Function

'------------------------------------------------------------------------------

Function AudioExt(FileName)

'Confirm file is only MP3

Dim FileNameLen, DotCheck, MyExt

FileNameLen=len(FileName) 
   DotCheck=instrrev(FileName, ".") 
   MyExt=right(FileName, FileNameLen-DotCheck) 
   if ucase(MyExt) = "MP3" then 
      AudioExt = True 
   else 
      AudioEXT = False 
   End if

End Function

'------------------------------------------------------------------------------ 
  
Sub PlaySelectedFiles()

'Determine next file to be played.

Dim strFilePath, strFile, strFileCheck 
   Dim strFilePathLen, LastSlash

If Reachable(strOwnedComputer.innerhtml) Then 
      INISet strOwnedComputer.innerhtml, strLocalFolder

For Each strFilePath In dictFiles.Keys

strFilePathLen=len(strFilePath) 
         LastSlash=instrrev(strFilePath, "\") 
         strFile=right(strFilepath, strFilePathLen-LastSlash) 
         strFileCheck=replace(strFile, " ", "") 
         strFileCheck=replace(strFileCheck, "'", "")

if DictNoFiles.Exists(strFileCheck) then 
            'msgbox strFileCheck&" is a deleted file, Skipping" 
         else 
            if DictPlayedFiles.Exists(strFileCheck) then 
               'msgbox strFileCheck&" is a played file, Skipping" 
            else 
               dictPlayedFiles.add strFileCheck, strFileCheck 
               'MsgBox "Playing "&strFilePath

PlayExecute strFilePath, strComputer, strFile                
               CurrentSong=strFileCheck 
               displayPageFull dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong  
               exit for 
            end if 
         end if

Else 
      msgbox strOwnedComputer.innerhtml&" is Unreachable!" 
      strOwnedComputer.innerhtml = strComputer 
   End If 
      
End Sub

'------------------------------------------------------------------------------

Sub PlayExecute (strFilePath, strComputer, strFile)

'Play selected file on specified computer.

Const OverwriteExisting = TRUE

Dim intProcessID 
   Dim objWMIService

'Script that does the business - Created on Own3d machine to play song 
   Dim Content : Content = _ 
   "on error resume next"&vbcrlf&_ 
   "Set objPlayer = CreateObject("&chr(34)&"WMPlayer.OCX.7"&chr(34)&")"&vbcrlf&_ 
   "objPlayer.URL = "&chr(34)&"c:\windows\test.mp3"&chr(34)&vbcrlf&_ 
   "while objPlayer.playstate = 9 OR objPlayer.playstate = 3"&vbcrlf&_ 
   "wscript.sleep 500"&vbcrlf&_ 
   "wend"&vbcrlf&_ 
   "Set objFSO = CreateObject("&chr(34)&"Scripting.FileSystemObject"&chr(34)&")"&vbcrlf&_ 
   "objFSO.DeleteFile WScript.ScriptFullName"

StopOJ

on error resume next

Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject") 
   objFSO.OpenTextFile("\\"&strComputer&"\C$\windows\rp.vbs", 2, True).WriteLine Content

objFSO.CopyFile strFilePath, _ 
       "\\"&strComputer&"\C$\windows\test.mp3", OverWriteExisting

Set objWMIService = GetObject _ 
       ("winmgmts:\\" & strComputer & "\root\cimv2:Win32_Process")

Dim Error : Error = objWMIService.Create _ 
       ("wscript c:\windows\rp.vbs", null, null, intProcessID)

if err<> 0 then 
      msgbox "Failed to play song" 
      exit sub 
   else 
      iTimerID = window.setInterval("CheckForSongEnd", 1000) 
   end if

on error goto 0

End Sub

'------------------------------------------------------------------------------ 
  
Function BrowseForFolder

'Browse for and select new source folder of MP3 files 
  
   Const BIF_NEWDIALOGSTYLE  = &H40 
   Const ssfDRIVES = &H11 
  
   Dim objShell : Set objShell = CreateObject("Shell.Application") 
   Dim objFolder : Set objFolder = objShell.BrowseForFolder(0, "Select Root Folder", BIF_NEWDIALOGSTYLE, ssfDRIVES) 
      
   If Not objFolder Is Nothing Then 
      BrowseForFolder = objFolder.Self.Path 
   Else 
      BrowseForFolder = "" 
   End If

DictNoFiles.RemoveAll 
   DictFiles.RemoveAll 
   DictPlayedFiles.RemoveAll

INISet strComputer, BrowseForFolder

End Function

'------------------------------------------------------------------------------

Sub displayPageFull(dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong)

'Display All music files in selected directory

DisplayHTML.innerhtml="" 
   Dim display, strFilePathLen, LastSlash, c 
   Dim strFilePath, strFile, strFileCheck, objOption

For Each strFilePath In dictFiles.Keys

strFilePathLen=len(strFilePath) 
      LastSlash=instrrev(strFilePath, "\") 
      strFile=right(strFilepath, strFilePathLen-LastSlash) 
      strFileCheck=replace(strFile, " ", "") 
      strFileCheck=replace(strFileCheck, "'", "")

if DictNoFiles.Exists(strFileCheck) then 
        'msgbox strFileCheck&" is a deleted file, Skipping" 
      else 
         c=c+1 
         if DictPlayedFiles.Exists(strFileCheck) then 
            'msgbox strFileCheck&" is a played file, Appling different formatting" 
            if CurrentSong=strFileCheck then 
               display=display&"<tr><td bgcolor=c0c0c0>"&"<input style='color:black; background-color:#99b3cc' class=button type=button value=X onClick=ItemRemove('"&strFileCheck&"')></td><td bgcolor=#0048f1 width=100%><span id=x"&c&" onclick=JumpOJ("&c&") onmouseover=Pointer onmouseout=DefaultCursor><font color=white >"&strfile&"</font></span></td></tr>"          
            else 
               display=display&"<tr><td bgcolor=c0c0c0>"&"<input style='color:black; background-color:#99b3cc' class=button type=button value=X onClick=ItemRemove('"&strFileCheck&"')></td><td bgcolor=b7c8f3 width=100%><span id=x"&c&" onclick=JumpOJ("&c&") onmouseover=Pointer onmouseout=DefaultCursor><font color=navy >"&strfile&"</font></span></td></tr>"          
            end if 
         else 
            display=display&"<tr><td bgcolor=f6f6f6>"&"<input style='color:black; background-color:#99b3cc' class=button type=button value=X onClick=ItemRemove('"&strFileCheck&"')></td><td bgcolor=e8ebf3 width=100%><span id=x"&c&" onclick=JumpOJ("&c&") onmouseover=Pointer onmouseout=DefaultCursor><font color=blue >"&strfile&"</font></span></td></tr>"          
         end if 
      end if

if c>0 then 
      DisplayHTML.innerhtml="<table>"&display&"</table><br><input style='color:black; background-color:#99b3cc' class=button type=button value=Play onClick=PlaySelectedFiles>" 
      PlayButton.disabled = false 
   else 
      DisplayHTML.innerhtml="<table>"&display&"</table><br>No files loaded" 
      PlayButton.disabled = true 
   end if

end sub

'------------------------------------------------------------------------------

Function JumpOJ(JumpToOJ)

Dim strFilePathLen, LastSlash, X 
   Dim strFilePath, strFile, strFileCheck

DictPlayedFiles.RemoveAll 
   JumpToOJ=JumpToOJ-1

For Each strFilePath In dictFiles.Keys

strFilePathLen=len(strFilePath) 
      LastSlash=instrrev(strFilePath, "\") 
      strFile=right(strFilepath, strFilePathLen-LastSlash) 
      strFileCheck=replace(strFile, " ", "") 
      strFileCheck=replace(strFileCheck, "'", "")

if DictNoFiles.Exists(strFileCheck) then 
        'msgbox strFileCheck&" is a deleted file, Skipping" 
      else 
         if JumpToOJ=0 then 
            PlaySelectedFiles 
            exit Function 
         else 
            DictPlayedFiles.add strFileCheck, strFileCheck 
            x=x+1

if x = JumpToOJ then 
               PlaySelectedFiles 
               exit Function 
            end if 
         end if 
      end if

end Function

'------------------------------------------------------------------------------

sub ReloadOJ

'Rebuild play list from scratch

DictNoFiles.RemoveAll 
   DictPlayedFiles.RemoveAll 
   displayPageFull dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong 
   StopOJ

End sub

'------------------------------------------------------------------------------

Function CheckForSongEnd

'Check for end of song and kick of next one

dim filesys, path

Set filesys = CreateObject("Scripting.FileSystemObject") 
   path = filesys.GetAbsolutePathName("\\"&strComputer&"\C$\windows\rp.vbs")

If filesys.FileExists(path) Then 
      'msgbox "Script file exists therefore still playing" 
   else 
      'msgbox "finished playing" 
      window.clearInterval(iTimerID) 
      PlaySelectedFiles 
   End If

end Function

'------------------------------------------------------------------------------

sub ReplayOJ

'Clear played list and play from top

DictPlayedFiles.RemoveAll 
   PlaySelectedFiles

End sub

'------------------------------------------------------------------------------

Sub StopOJ

'Stop music playing

window.clearInterval(iTimerID) 
  
   CurrentSong="" 
   displayPageFull dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong

If Reachable(strOwnedComputer.innerhtml) Then

Dim objWMIService, objProcess, colProcess 
      Dim strProcessKill : strProcessKill = "'wscript c:\\windows\\rp.vbs'"

on error resume next 
      Set objWMIService = GetObject("winmgmts:" _ 
         & "{impersonationLevel=impersonate}!\\" _ 
            & strComputer & "\root\cimv2")

if err<> 0 then 
         Dim objNet : Set objNet = CreateObject("WScript.NetWork")
         MsgBox (strComputer& " is not responding, reverting to "&objNet.ComputerName&"'s speakers") 
         strcomputer = ucase(objNet.ComputerName)
         strOwnedComputer.innerhtml = strComputer 
         INISet strComputer, strLocalFolder 
         exit sub
      end if 
      on error goto 0

Set colProcess = objWMIService.ExecQuery _ 
         ("Select * from Win32_Process Where CommandLine = " & strProcessKill )

For Each objProcess in colProcess 
         objProcess.Terminate() 
      Next

on error resume next
      Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject") 
      objFSO.DeleteFile("\\"&strComputer&"\C$\windows\rp.vbs") 
      on error goto 0

end if

End Sub

'------------------------------------------------------------------------------

Sub SelectSpeakers

'Select remote computer's speakers (Can use your own)

Dim strComputerPing : strComputerPing = inputbox("Enter netbios name of the computer's "&vbcrlf&"speakers that you want to own.", "Owned Jukebox", strComputer) 
   if strComputerPing = "" then exit sub 
   if reachable(strComputerPing) then 
      StopOJ 
      strComputer = ucase(strComputerPing) 
      strOwnedComputer.innerhtml = strComputer 
      INISet strComputer, strLocalFolder 
      CurrentSong="" 
      displayPageFull dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong  
   else 
      msgbox strComputerPing & " is not reachable." 
   end if

end sub

'------------------------------------------------------------------------------

Sub CloseOJ

'Stop play and close script

StopOJ 
   AboutOJ 
   self.close

end sub

'------------------------------------------------------------------------------

function ItemRemove(strItem)

'Remove item from play list

DictNoFiles.add strItem, strItem 
   displayPageFull dictFiles, dictNoFiles, dictPlayedFiles, CurrentSong

if strItem=CurrentSong then StopOJ

End function

'------------------------------------------------------------------------------

Function Reachable(strComputer)

'check if remote computer is reachable via ping.

Dim wmiQuery, objWMIService, objPing, objStatus 
  
   wmiQuery = "Select * From Win32_PingStatus Where Address = '" & strComputer & "'" 
  
   Set objWMIService = GetObject("winmgmts:\\.\root\cimv2") 
   Set objPing = objWMIService.ExecQuery(wmiQuery) 
  
   For Each objStatus in objPing 
      If IsNull(objStatus.StatusCode) Or objStatus.Statuscode<>0 Then 
         Reachable = False 'if computer is unreachable, return false 
      Else 
         Reachable = True 'if computer is reachable, return true 
      End If 
   Next

End Function

'------------------------------------------------------------------------------

Sub Pointer 
    document.body.style.cursor = "hand" 
End Sub

'------------------------------------------------------------------------------

Sub DefaultCursor 
    document.body.style.cursor = "default" 
End Sub

'------------------------------------------------------------------------------

</script>

</head>

<table width=100% border=0 cellspacing=0 cellpadding=5 style="filter:progid:DXImageTransform.Microsoft.Gradient(endColorstr='#e8ebf3', startColorstr='#0048f1', gradientType='1');"> 
   <tr> 
      <td><b><font color = #e8ebf3> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="MainGetFiles"> BROWSE <br> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="SelectSpeakers"> SPEAKERS <br> 
         <input style="color:black; background-color:#99b3cc" type="button" id="PlayButton" value=">" onclick="PlaySelectedFiles"> PLAY/NEXT <br> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="ReplayOJ"> REPLAY <br> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="StopOJ"> STOP <br> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="ReloadOJ"> RELOAD <br> 
         <input style="color:black; background-color:#99b3cc" type="button" value=">" onclick="CloseOJ"> CLOSE <br></b></font> 
      </td> 
      <td width=50%> 
         <center> 
         <b><i><font size=6 color=#001649>0wn3d <br><font size=5>JukeBox</i> 
         <br> 
         <span id="strOwnedComputer"> Speakers </span></b></font></font> 
         </center> 
      </td> 
   </tr> 
   <tr> 
      <td colspan=2 bgcolor="#e8ebf3"><font color=#001649> 
         <b>Source Directory: </b> 
         <marquee scrollamount="1" scrolldelay="10" direction="left" width=100% height="20" behavior=alternate><i> <span id="root_path">  </span></i> 
         </marquee></font> 
      </td> 
   </tr> 
   <tr> 
      <td colspan=2> 
         <span id=DisplayHTML>No files loaded</span> 
      </td> 
   </tr> 
</table>

</td> 
   </tr> 
</table> 
</center> 
</DIV>

</body> 
</html>

Attachment (1)

< Message edited by TomRiddle -- 8/6/2008 10:01:02 PM >

Revisions: 4 | Post #: 1

RE: Own3d Jukebox - 8/4/2008 12:52:06 AM

p0ng

Posts: 33
Score: 0
Joined: 6/18/2008
Status: offline

nice work!

(in reply to TomRiddle)

Post #: 2

RE: Own3d Jukebox - 8/4/2008 5:11:32 PM

djredmar

Posts: 61
Score: 0
Joined: 12/11/2006
From: Europe, The Netherlands
Status: offline

Looks nice man!

(in reply to p0ng)

Post #: 3

RE: Own3d Jukebox - 8/6/2008 12:37:00 AM

AMBience

Posts: 5
Score: 0
Joined: 7/24/2008
Status: offline

Interesting.

(in reply to djredmar)

Post #: 4

RE: Own3d Jukebox - 8/6/2008 1:44:50 PM

TomRiddle

Posts: 191
Score: 4
Joined: 2/7/2008
Status: offline

Thanks for the interest. I am going to update the original post tonight with some more minor enhancements.

AMBience, I had a look at your original Sine and had a go at using one of those effects in the player but seemed to make it a bit top heavy and the waveform was obviously not responsive to the sound as it is. But anyway that might make another interesting project to do in vbscript.

The only other features I can think that would make this script better are a volume control and maybe a repeat button. I am going to investigate if accessing the volume control via vbscript is feasible.

(in reply to AMBience)

Post #: 5

RE: Own3d Jukebox - 8/7/2008 2:05:53 AM

AMBience

Posts: 5
Score: 0
Joined: 7/24/2008
Status: offline

Hi Tom,
Visualizations would indeed be cool, getting it to react to the music however would be impossable...I think! (never say never in VBS, is my motto)

As for your code...Multiple "interesting" really :-) Very nice interface, good music taste, but I'm confused about the music player code. I'm guessing that's the only way to play music in pure VBS? Funny enough I have been experementing a lot with sound and music in HTAs recently. I've found that including a ClassID instead of the usual embedded sound in a HTA exposes some very nice commands to the DOM.

Drop this into your HTML part of the HTA...

<OBJECT ID="MyPlayer" WIDTH="0" HEIGHT="0" CLASSID="clsid:22D6F312-B0F6-11D0-94AB-0080C74C7E95"><PARAM NAME="AutoStart" VALUE="false"></OBJECT>

This is Media player 6 (I use this for compatability and low resource use) You can now use these very cool commands......

[Loading]
MyPlayer.Filename = "C:\Music\Reign in blood.mp3"

[Setup]
MyPlayer.Balance = 0 (-2000=Left 0=Middle 2000=Right)
MyPlayer.Volume = 5000 (-5000=Silence 5000=Full blast)

[Playing]
MyPlayer.Play
MyPlayer.Pause
MyPlayer.Stop
MyPlayer.CurrentPosition = 1.234 (milliseconds)

[FX]
MyPlayer.Rate = 1.5 (0.001= Very slow, 1=Normal, 1.999=Very fast)

This last one changes the actual pitch of the music, so it's only good for sound FX (or a piano program :-) ) It took me ages to find out the boundries, even w3schools are very vague about them. You can also test all the above values, but you need to do it inside a fast loop (SetInterval 1) for any position type code, Like:-

Sub PlayLoop()
If MyPlayer.CurrentPosition => 3.123 then MyPlayer.CurrentPosition = 2.000
End Sub

This will loop the song at that place forever....
Have fun!

(in reply to TomRiddle)

Post #: 6

RE: Own3d Jukebox - 8/7/2008 11:31:26 AM

TomRiddle

Posts: 191
Score: 4
Joined: 2/7/2008
Status: offline

Thanks, I will check out your code AMBience, if I can get all those extra controls working might be worth my while redesigning the interface, maybe copy something like a winamp player layout.
It looks like the only other technique for volume control is sendkeys on sndvol32.exe but that's for the master volume so it might still be useful if clunky.

Rock On

(in reply to AMBience)

Post #: 7

RE: Own3d Jukebox - 8/12/2008 1:38:51 AM

p0ng

Posts: 33
Score: 0
Joined: 6/18/2008
Status: offline

quote:

ORIGINAL: TomRiddle

Thanks, I will check out your code AMBience, if I can get all those extra controls working might be worth my while redesigning the interface, maybe copy something like a winamp player layout.
It looks like the only other technique for volume control is sendkeys on sndvol32.exe but that's for the master volume so it might still be useful if clunky.

Rock On

Post your code if you get it updated.

(in reply to TomRiddle)