Not Been Accessed In X Days

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Not Been Accessed In X Days

Logged in as: Guest

arrSession:exec spGetSession 2,16,63335

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Not Been Accessed In X Days
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Not Been Accessed In X Days - 8/11/2008 11:46:45 PM

xITz your FEARx

Posts: 3
Score: 0
Joined: 8/11/2008
Status: offline

As far as I know, this works completely, I have not had any problems with it. Ok so anyway, this scripts will search for all files that have not been accessed in or over x days, x being the user define value. The logging does not work, I am to lazy to fix it, but really you can make it log anyway with > logfile.txt...

So anyway this is how you use it.

blahblah>cscript AccessedX.vbs "The Root Directory" X

Root directory being the starting folder you wish it to search from, and X being the amount of days it has not been accessed in.

So here it is and tell me what you think. Btw, I based this off of another VBScript I had with me, so I didnt have to type as much.

Edit: Oh right... It works by accessing the files meta data, not actually accessing the file. So it will not change the last accessed date.

Edit 2 : I fixed the logger

'====================
'
' NAME:    AccessedX.vbs
'
' AUTHOR:    xITz your FEARx
' DATE:    8/12/08
'
' COMMENT:AccessedX will search the directory that you tell it to for files that
'            have not been accessed in over days
'        
' USAGE:    CScript AccessedX.vbs <rootfolder> <AccessedX> [/L:logfile]
'
' <rootfolder> - Specifies the directory to start purging files.
' <accessedx> - Specifies how old a file can be in Days before it is purged.
' [/L:logfile] - Specifies a file to output the results to.
' /? - Displays USAGE message.
'
'====================

Const EVENT_SUCCESS = 0
Const EVENT_ERROR = 1
Const EVENT_WARNING = 2
Const EVENT_INFORMATION = 4

Dim objFSO, objWSH, objLogFile
Dim argCount, iArg, flg
Dim RootFolder, AccessedX, Logfile

On Error Resume Next

Set objWSH = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

argCount = WScript.Arguments.Count
iArg = 0

' Check to see if the user is asking for help.
If argCount > 0 Then
   flg = LCase(WScript.Arguments(0))
   If (flg="help") Or (flg="/h") Or (flg="\h") Or (flg="-h") Or (flg="h") Or _
    (flg="/?") Or (flg="\?") Or (flg="-?") Or (flg="?") Then
       Call ShowUsage
   End If
End If

' Make sure that we have at least 2 arguments.    
If argCount < 2 Then
   Call Fail("Usage: " & WScript.ScriptName & " /? for help.")
End If

' Verify that the first argument is a folder and it exists.
RootFolder = NextArgument
If Not objFSO.FolderExists(RootFolder) Then
   Call Fail("Can't find " & chr(34) & RootFolder & chr(34) & ".")
End If

' Verify that the second argument is a valid number of days.
AccessedX = NextArgument
If IsNumeric(AccessedX) Then
   If (AccessedX >= 1) Then
       AccessedX = Int(AccessedX)
   Else
       Call Fail("Invalid entry.")
   End If
Else
   Call Fail("Invalid entry.")
End If

' If we have more than 2 arguments then error out.
If Not IsEmpty(NextArgument)Then
   Call Fail("Usage: " & WScript.ScriptName & " /? for help.")
End If

' Open the logfile if it was an option.
If Not IsEmpty(Logfile) Then
   Set objLogFile = objFSO.CreateTextFile(Logfile, True)
   Call CheckError
End If

' Everything should be ok so proceed with the scanning.
Call LogEvent("Files that have not been accessed in at least " & AccessedX & " days" & vbCrLf)
Call ScanFolder(RootFolder)

' Clean up.
Set objWSH = Nothing
Set objFSO = Nothing
If Not IsEmpty(Logfile) Then objLogFile.Close

' Exit the script.
WScript.Quit 0

'====================
Sub ScanFolder(sFolderName)

Dim objFolder, objSubFolders, objFiles
Dim Folder, File
Dim ret

On Error Resume Next

Set objFolder = objFSO.GetFolder(sFolderName)
Set objSubFolders = objFolder.SubFolders
Set objFiles = objFolder.Files

For Each Folder In objSubFolders
   ScanFolder (Folder.Path)
Next

For Each File In objFiles
   ret = DaysOld(File.Path)
   ' If the file older then the wanted # of days then log it
   If ret => AccessedX Then
           If StrComp(File.Path, Logfile, vbTextCompare) <> 0 Then
               Call LogEvent(File.Path & " has not been accessed in " & ret & " days.")
               Call CheckError
           End If
   End If
Next

End Sub

'====================
Function DaysOld(sFileName)

Dim objFile

On Error Resume Next

Set objFile = objFSO.GetFile(sFileName)
Call CheckError

' Return the difference in days.
DaysOld = Int(Now() - objFile.DateLastAccessed)

End Function

'====================
' Extract argument value from command line, processing any option flags.
Function NextArgument

Dim arg

Do ' Loop to pull in option flags until an argument value is found.
   If iArg >=argCount Then Exit Function
   arg = WScript.Arguments(iArg)
   iArg = iArg + 1
   If (AscW(arg) <> AscW("/")) And (AscW(arg) <> AscW("-")) Then Exit Do
   Select Case UCase(Right(arg, Len(arg) -1))
       Case Else
           If UCase(Mid(arg, 2, 2)) = "L:" Then
               LogFile = Mid(arg,4)
           Else
               Call Fail("Invalid option flag: " & arg)
           End If
   End Select
Loop

NextArgument = arg

End Function

'====================
Sub ShowUsage

WScript.Echo "CScript " & WScript.ScriptName & " <rootfolder> <AccessedX>" & vbCrLf & _
            vbTab & vbTab & vbTab & vbTab & vbTab & " [/L:logfile]" & vbCrLf & vbCrLf & _
            " rootfolder" & vbTab & "Specifies the directory to start searching in." & vbCrLf & _
            " AccessedX" & vbTab & "Specifies how many days since it has been accessed." & vbCrLf & _
            " /L:logfile" & vbTab & vbTab & "Specifies a file to output the results to." & _
            " /?" & vbTab & vbTab & "Displays this message."
WScript.Quit 1

End Sub

'====================
Sub CheckError()

Dim msg

If Err.Number = 0 Then Exit Sub
msg = Err.Source & " " & Hex(Err) & ": " & Err.Description

Call Fail(msg)

End Sub

'====================
Sub LogEvent(sMessage)

If IsObject(objLogFile) Then objLogFile.WriteLine(sMessage)

End Sub

'====================
Sub LogToEventLog(sMessage, nValue)

If bEventLog Then objWSH.LogEvent nValue, WScript.ScriptName & ": " & sMessage

End Sub

'====================
Sub Fail(sMessage)

If bEventLog Then LogToEventLog sMessage, EVENT_ERROR
If IsObject(objLogFile) Then
   objLogFile.WriteLine(WScript.ScriptName & ": " & sMessage)
   objLogFile.Close
End If
WScript.Echo WScript.ScriptName & ": " & sMessage

WScript.Quit(1)

End Sub

< Message edited by xITz your FEARx -- 8/12/2008 2:04:31 AM >